CALL IS8601_CONVERT Routine

data _null_;
      /* Declare variable length and type. Character datetime and duration   */
      /* values must be at least 16 characters. To avoid losing precision,   */
      /* the numeric datetime value has a length of 8.                       */
   length dtN duN 8 dtC duC $16 intervalC $32;
      /* Assign a numeric datetime value and a character duration value.     */
   dtN='15Sep2011:09:00:00'dt;
   duC=input('P2y3m4dT5h6m7s', $n8601b.);
   put dtN=;
   put duC=;
      /* Create an interval from a datetime and duration value and format the */
      /* interval using the ISO 8601 extended notation for character values.  */
   call is8601_convert('dt/du', 'intvl', dtN, duC, intervalC);
   put '**  Character interval created from datetime and duration values **/';
   put intervalC $n8601e.;
   put ' ';
      /* Create numeric datetime and duration values from an interval and     */
      /* format the values using the ISO 8601 extended notation for numeric   */
      /* values.                                                              */
   call is8601_convert('intvl', 'dt/du', intervalC, dtN, duN);
   put '**  Character datetime and duration created from an interval  **/';
   put dtN=;
   put duN=;
   put ' ';
      /* Assign a new datetime value with omitted components.                  */
   dtC=input('2012---15T10:-:-', $n8601b.);
   put '** This datetime is a character value. **';
   put dtC $n8601h.;
   put ' ';
      /* Create an interval by reading a datetime value that has omitted date  */
      /* and time components.  Use replacement values for the month, minutes,  */
      /* and seconds.                                                          */
   call is8601_convert('du/dt', 'intvl', duC, dtC, intervalC, , 7, , , 35, 45);
   put '**  Interval created using a datetime with omitted values,      **';
   put '**  inserting replacement values for month (7), minute (35)     **';
   put '**  seconds (45).                                               **';
   put intervalC $n8601e.;
   put ' ';
run;

data _null_;
   length mynew $32;
   x='P8w';
   y='11feb2012:12:35:22'dt;
   call is8601_convert('du/dt', 'intvl', x, y, mynew);
   put mynew=$n8601e.;
run;

data temp;
   length dt $32;
   x='P6w';
   y='11feb2012:11:13:22'dt;
   call is8601_convert('du/dt', 'start', x, y, dt);
   put dt=$n8601e.;
run;

data _null_;
   infile datalines;
   input mo d yr hour min sec; 
   length mynew $32;
   x='P8w';
   call is8601_convert('du/dt6', 'intvl', x, mo, d, yr, hour, min, sec, mynew);
   put mynew=$n8601e.;
   datalines;
02 22 2011 10 30 45
12 13 2010 12 35 25
03 26 2010 10 10 10
;
run;

data temp;
   input y mo d h min s;
   length mynew $16;
      /* This value is the duration. */
   x='P2w';
      /* This CALL routine uses the date and time values that are */
      /* listed in the data lines to create a DATETIME value.     */
   call is8601_convert('dt6', 'dt', y, mo, d, h, min, s, dt);
   put dt=datetime.;
      /* This CALL routine uses the DATETIME value that was previously */
      /* created.                                                      */
   call is8601_convert('du/dt', 'start', x, dt, mynew);
   put mynew=$n8601e.;
datalines;
2011 6 7 10 15 20
2011 12 5 10 25 45
2011 6 30 10 32 20
;

data a;
   x='P8w';
   call is8601_convert('du', 'du', x, mynew);
   put mynew=time8.;
run;

data a;
   length mynew $32;
   x='P8w';
   y='11feb2012:12:22'dt;
   call is8601_convert('du/dt', 'intvl', x, y, mynew);
   put mynew=$n8601e.;
run;

data a;
   length mynew $16;
      /* If you omit the LENGTH statement, replace the PUT statement */
      /* with 'put mynew datetime22.;'.                              */
   x='P8w';
   y='11feb2012:12:22'dt;
   call is8601_convert('du/dt', 'start', x, y, mynew);
   put mynew=$n8601e.;
run;

data _null_;
   x='1271:59:00';
   time=input(x, time10.);
   length dur $16;
   call is8601_convert('du', 'du', time, dur);
   put dur=$n8601e.;
run;

data a;
   length dur $16;
   start='02apr2012:12:30:22'dt;
   end='08apr2012:14:32:22'dt;
   call is8601_convert('dt/dt', 'du', start, end, dur);
   put dur=$n8601e.;
run;

data _null_;
   length Final2 $16;
   int=input('2012-03-15T14:32:00/2012-03-29T09:45:00', $n8601e40.);
   call is8601_convert('intvl', 'dt/du', int, Final1, Final2);
   put Final1= / Final2=$n8601e.;
run;