CALL RANNOR Routine

Returns a random variate from a normal distribution.

Category:	Random Number
Restriction:	This function is not valid on the CAS server.
Note:	Argument types for arguments that are updated must match in CALL routines. All argument types must be CHAR, VARCHAR, or NUMERIC. If the argument types do not match, a warning is issued to the log.

Table of Contents

Syntax

CALL RANNOR(seed, x);

Required Arguments

seed

is the seed value. A new value for seed is returned each time CALL RANNOR is executed.

Range	seed < 2³¹ - 1
Note	If seed ≤ 0, the time of day is used to initialize the seed stream.
See	Seed Values and Comparison of Seed Values in Random-Number Functions and CALL Routines for more information about seed values

x

is a numeric variable. A new value for the random variate x is returned each time CALL RANNOR is executed.

Details

The CALL RANNOR routine updates seed and returns a variate x that is generated from a normal distribution, with mean 0 and variance 1.

By adjusting the seeds, you can force streams of variates to agree or disagree for some or all of the observations in the same, or in subsequent, DATA steps.

The CALL RANNOR routine uses the Box-Muller transformation of RANUNI uniform variates.

For a discussion and example of an effective use of the random number CALL routines, see Starting, Stopping, and Restarting a Stream.

Comparisons

The CALL RANNOR routine gives greater control of the seed and random number streams than does the RANNOR function.

Example

This example uses the CALL RANNOR routine:

data u1(keep=x);
   seed=104;
   do i=1 to 5;
      call rannor(seed, X); 
      output;
   end;
   call symputx('seed', seed);
run;

data u2(keep=x);
   seed=&seed;
   do i=1 to 5;
      call rannor(seed, X); 
      output;
   end;
run;

data all;
   set u1 u2;
   z=rannor(104);
run;

proc print label;
   label x='Separate Streams' z='Single Stream';
run;

Output from the CALL RANNOR Routine

CALL RANNOR Routine

Syntax

Required Arguments

seed

x

Details

Comparisons

Example

See Also