INTINDEX Function

data weekly;
     *do year=2007 to 2012;
     year=2004;
        NewYear=holiday('NEWYEAR', year);
        do i=-5 to 5; 
           date=intnx('week', NewYear, i);
           output;
        end;
     *end;
     format date date.;
			format NewYear date.;
run;

/* The standard leap week is the first week of year. */
/* An alternative method uses a third argument:leap week is week 53. */
title "Using a Third Argument to Control Weekly Seasonality";
data LeapWeekExample;
     set weekly;
     StandardIndex=intindex('week', date);
     IndexWithLeap=intindex('week', date, 53);
run;
proc print;
run;

/* Using a number and an interval can be equivalent for the third argument. */
title "Using the Third Argument as a Number or Cycle";
data Equiv3rdArg;    
     set sashelp.air(obs=12);
     defaultSeasonal=intindex('MONTH', date);
     SeasonalArg12=intindex('MONTH', date, 12);
     SeasonalArgYear=intindex('MONTH', date, 'YEAR');
     format date date.;
run;
proc print;
run;


/* Use the third argument for non-standard seasonality. */
title "Using the Third Argument for Non-Standard Seasonality";
data NonStandardSeasonal;
     set sashelp.air(obs=24);
     /* Standard Index - MONTH is Yearly Seasonal */
     StandardIndex=intindex('MONTH', date);
     SemiYrIndex=intindex('MONTH', date, 'SEMIYR');
     Index6=intindex('MONTH', date, 6);
     format date date.;
run;

proc print;
run;