Network Action Set

This section contains PROC CAS code.

Note: Input data must be accessible in your CAS session, either as one or more CAS tables or as one or more transient-scope tables. A CAS table has a two-level name: the first level is your CAS engine libref, and the second level is the table name. You refer to this table in the CAS procedure by specifying only the second level. For more information about two-level names, see Chapter 2, Shared Concepts (SAS Viya: Machine Learning Procedures). A transient-scope table is called directly from the action and exists in memory for the duration of the action. For more information about accessing data, see SAS Viya: System Programming Guide. For more information about PROC CAS and programming in CASL, see SAS Cloud Analytic Services: CASL Programmer’s Guide and SAS Cloud Analytic Services: CASL Reference.

This section illustrates the calculation of summary statistics on the directed graph G shown in Figure 22.

Figure 22: A Directed Graph G

You can represent the directed graph G by using the following nodes data set, NodeSetIn, and links data set, LinkSetIn:

data NodeSetIn;
  input node $ @@;
  datalines;
A B C D E F G H I J K L M N O P
;
data LinkSetIn;
   input from $ to $ weight @@;
   datalines;
A B 1 A C 2 A D 2 B A 2 D E 2
D F 1 E F 2 F D 2 F E 1 A A 2
A B 2 I J 5 K L 3 K M 2 N O 1
P O 5
;

The following DATA steps load the NodeSetIn and LinkSetIn data sets into CAS data tables named mylib.NodeSetIn and mylib.LinkSetIn. These statements assume that the CAS engine libref is named mylib, but you can substitute any appropriately defined CAS engine libref.

data mylib.NodeSetIn;
   set NodeSetIn;
run;
data mylib.LinkSetIn;
   set LinkSetIn;
run;

The following statements calculate the default summary statistics and produce information about the connectedness of the graph. They output the results in the data tables NodeSetOut and Summary.

proc cas;
   loadactionset "network";
   action network.summary result=r status=s /
      direction   = "directed"
      indexOffset = 1
      nodes       = {name = "NodeSetIn"}
      links       = {name = "LinkSetIn"}
      outNodes    = {name = "NodeSetOut", replace=true}
      out         = {name = "Summary", replace=true}
      connectedComponents = true;
  run;
  print r.ProblemSummary; run;
  print r.SolutionSummary; run;
  action table.fetch / table = "NodeSetOut"; run;
  action table.fetch / table = "Summary"; run;
quit;

The problem summary output from this action is shown in Output 28.19.1.

The solution summary output from this action is shown in Output 28.19.2.

The output data table NodeSetOut contains the node-level summary metrics of the input graph, as shown in Output 28.19.3.

The output data table Summary contains the summary statistics of the input graph, as shown in Output 28.19.4.