Network Action Set

This section contains PROC CAS code.

Note: For more information about PROC CAS and programming in CASL, see SAS Cloud Analytic Services: CASL Programmer’s Guide and SAS Cloud Analytic Services: CASL Reference.

This example shows how to input a molecular graph by specifying a Simplified Molecular Input Line Entry System (SMILES) string in the readGraph or loadGraph action.

The following statements read in a SMILES string, specify adding hydrogen atoms to the molecular graph, and output the resulting links and nodes data tables. These statements do not run any algorithms, but you can use the resulting output as input data for subsequent network actions.

proc cas;
   loadactionset "network";
   action network.readGraph result=r status=s /
      smiles    = {smilesStr = "Cc1nc(c[nH]1)N(=O)=O", addHydrogens=true}
      outNodes  = {name = "NodeSetOut", replace=true}
      outLinks  = {name = "LinkSetOut", replace=true};
   run;
   print r.ProblemSummary; run;
   action table.fetch / table = "NodeSetOut"; run;
   action table.fetch / table = "LinkSetOut"; run;
quit;

The problem summary output from this action is shown in Output 28.18.1.

The output data table NodeSetOut, shown in Output 28.18.2, now contains the nodes of the molecular graph and the node attributes that are associated with each atom.

The output data table LinkSetOut, shown in Output 28.18.3, contains the links of the molecular graph and the link attributes that are associated with each bond.

The molecular graph, shown in Figure 21, uses conventional colors to differentiate chemical elements and edge styles to differentiate bond types.

Figure 21: Molecular Graph

You can also load a molecular graph by using the loadGraph action. The following statements demonstrate an alternative way to specify the molecular graph, by providing a SMILES string itself as input:

proc cas;
   loadactionset "network";
   action network.loadGraph result=rl status=s /
      smiles       = "c1ccccc1"
      outGraphList = {name = "OutGraphList", replace=true};
   run;
   action table.fetch / table = "OutGraphList"; run;
quit;

The graph identifier and several other pieces of summary information about the in-memory graph are now contained in the output data table OutGraphList, as shown in Output 28.18.4.