Network Action Set

Calculating the Transitive Closure of a Directed Graph

This section contains PROC CAS code.

Note: Input data must be accessible in your CAS session, either as a CAS table or as a transient-scope table. A CAS table has a two-level name: the first level is your CAS engine libref, and the second level is the table name. You refer to this table in the CAS procedure by specifying only the second level. For more information about two-level names, see Chapter 2, Shared Concepts (SAS Viya: Machine Learning Procedures). A transient-scope table is called directly from the action and exists in memory for the duration of the action. For more information about accessing data, see SAS Viya: System Programming Guide. For more information about PROC CAS and programming in CASL, see SAS Cloud Analytic Services: CASL Programmer’s Guide and SAS Cloud Analytic Services: CASL Reference.

This example illustrates the use of the transitive closure algorithm on the directed graph G shown in Figure 24.

Figure 24: A Directed Graph G

The directed graph G can be represented by the following links data set, LinkSetIn:

data LinkSetIn;
   input from $ to $ @@;
   datalines;
B C  B D  C B  D A  D C
;

The following DATA step loads the LinkSetIn data set into a CAS data table named mylib.LinkSetIn. These statements assume that the CAS engine libref is named mylib, but you can substitute any appropriately defined CAS engine libref.

data mylib.LinkSetIn;
   set LinkSetIn;
run;

The following statements calculate the transitive closure and output the results in the data table TransClosure:

proc cas;
   loadactionset "network";
   action network.transitiveClosure result=r status=s /
      direction = "directed"
      links     = {name = "LinkSetIn"}
      out       = {name = "TransClosure", replace=true};
   run;
   print r.ProblemSummary; run;
   print r.SolutionSummary; run;
   action table.fetch / table = "TransClosure"; run;
quit;

The problem summary output from this action is shown in Output 28.21.1.

Output 28.21.1: Problem Summary

Problem Summary
Number of Nodes	4
Number of Links	5
Graph Direction	Directed

The solution summary output from this action is shown in Output 28.21.2.

Output 28.21.2: Solution Summary

Solution Summary
Problem Type	Transitive Closure
Solution Status	OK
CPU Time	0.00
Real Time	0.00

The output data table TransClosure contains the transitive closure of G, as shown in Output 28.21.3.

Output 28.21.3: Transitive Closure of a Directed Graph

Selected Rows from Table TRANSCLOSURE
_Index_	from	to
1	B	C
2	B	D
3	B	B
4	B	A
5	C	B
6	C	C
7	C	D
8	C	A
9	D	A
10	D	C
11	D	B
12	D	D

The transitive closure of G is shown graphically in Figure 25.

Figure 25: Transitive Closure of G

Calculating the Transitive Closure of a Directed Graph

This section contains Lua code for the analysis in the CASL version of this example, which contains details about the results.

Note: In order to run this code, the data that are described in the CASL version need to be accessible to the CAS server. One way to do this is to convert the LinkSetIn data to the comma-separated-value (CSV) file LinkSetIn.csv and then use the following code to load the CSV file into CAS:

s:loadtable{casLib="casuser", path="LinkSetIn.csv"}

For more information about coding in Lua, see Getting Started with SAS Viya for Lua and SAS Viya: System Programming Guide.

The following statements calculate the transitive closure and output the results in the data table TransClosure:

s:network_transitiveClosure{
   direction = "directed",
   links     = {name = "LinkSetIn"},
   out       = {name = "TransClosure", replace=true}}

Calculating the Transitive Closure of a Directed Graph

This section contains Python code for the analysis in the CASL version of this example, which contains details about the results.

s.upload_file('LinkSetIn.csv')

For more information about coding in Python, see Getting Started with SAS Viya for Python and SAS Viya: System Programming Guide.

The following statements calculate the transitive closure and output the results in the data table TransClosure:

s.network.transitiveClosure(
    direction = "directed",
    links     = {"name": "LinkSetIn"},
    out       = {"name": "TransClosure", "replace":True})

Calculating the Transitive Closure of a Directed Graph

This example is not available for the R programming language.

Last updated: March 12, 2026