FRONTIER Procedure

This example shows how to estimate the three types of stochastic frontier cost models.

The data for the cost model are provided by Christensen and Greene (1976). The data describe costs and production inputs of 145 US electricity producers in 1955. The model that is estimated follows the nonhomogeneous version of the Cobb-Douglas cost function:

All dollar values are normalized by fuel price. The quadratic log of the output is added to capture nonlinearities due to scale effects in cost functions. Five new variables, log_C_PF, log_PK_PF, log_PL_PF, log_y, and log_y_sq, are created to reflect transformations. The following statements create the data set and transformed variables:

     title1 'Estimating a Stochastic Frontier Cost Model';

     data electricity;
        input Firm Year Cost Output LPrice LShare KPrice KShare FPrice FShare;
     datalines;
     1  1955  .0820  2.0  2.090  .3164  183.000  .4521  17.9000  .2315
     2  1955  .6610  3.0  2.050  .2073  174.000  .6676  35.1000  .1251
     3  1955  .9900  4.0  2.050  .2349  171.000  .5799  35.1000  .1852

   ... more lines ...   

 /* Data transformations */
 data electricity;
    set electricity;
    label Firm="firm index"
          Year="1955 for all observations"
          Cost="Total cost"
          Output="Total output"
          LPrice="Wage rate"
          LShare="Cost share for labor"
          KPrice="Capital price index"
          KShare="Cost share for capital"
          FPrice="Fuel price"
          FShare"Cost share for fuel";
    log_C_PF=log(Cost/FPrice);
    log_PK_PF=log(KPrice/FPrice);
    log_PL_PF=log(LPrice/FPrice);
    log_y=log(Output);
    log_y_sq=log_y**2/2;
 run;

 data mylib.electricity;
     set electricity;
  run;

The following statements estimate a stochastic frontier exponential cost model that uses the Christensen and Greene (1976) data:

 /*-- Stochastic Frontier Cost Model --*/
 proc frontier data=mylib.electricity;
    model log_C_PF = log_PK_PF log_PL_PF log_y log_y_sq / type=exponential cost;
 run;

Output 19.2.1 shows the results.

Similarly, the stochastic frontier cost model can be estimated using the TYPE=HALF or TYPE=TRUNCATED option, which represents half-normal or truncated-normal errors, respectively.

The following statements estimate the half-normal model:

/*-- Stochastic Frontier Cost Model --*/
proc frontier data=mylib.electricity;
   model log_C_PF = log_PK_PF log_PL_PF log_y log_y_sq / type=half cost;
run;

Output 19.2.2 shows the result.

The following statements estimate the truncated-normal model:

/*-- Stochastic Frontier Cost Model --*/
proc frontier data=mylib.electricity;
   model log_C_PF = log_PK_PF log_PL_PF log_y log_y_sq / type=truncated cost;
run;

Output 19.2.3 shows the results.