FRONTIER Procedure

This example shows how to estimate a stochastic frontier production model in which the inefficiency term has a truncated-normal distribution.

The following DATA step generates a data table that contains 100,000 observations from this model. The model contains three input variables, one of which is a classification variable.

    data input_dataset;
       keep y x1 x2 cl j;
       call streaminit(24569);
         do j = 1 to 100000;
            x1 = 2 + rand("normal");
            x2 = rand("uniform");
            cl = rand("bernoulli",0.4);
            sigma_v  = rand("normal");
            sigma_u = 0;
            do until(sigma_u > 0);
               sigma_u = rand("normal",0.75,1.3);
            end;
            xb = 5 - 0.5*x1 + 0.8*x2 - 0.65*(cl = 0);
            y  =  xb + sigma_v - sigma_u;
            output;
         end;
    run;

    data mylib.input_dataset;
       set input_dataset;
    run;

The following statements estimate the model:

 /*-- Stochastic Frontier Production Model: Truncated-Normal --*/
 proc frontier data=mylib.input_dataset method=quanew;
    class cl;
    model y = x1 x2 cl/ production type=trunc;
 run;

Output 19.1.1 shows the results.

In addition to the parameters that are estimated for the other stochastic frontier models, PROC FRONTIER also estimates the parameter _Mu for truncated-normal models. _Mu is the mean of the truncated-normal distribution. The parameter cl_1 indicates the classification variable for the level 1 and is dropped in the estimation to prevent perfect collinearity in the model. For more information, see the section Dropping a Class-Level Parameter to Avoid Collinearity.