SASEBLS Interface Engine

This example shows how to retrieve American Time Use Survey (ATUS) data. You can view these data by using the following URL:

https://www.bls.gov/tus/database.htm

INSERIES is an input SAS data set that lists the IDs of the time series to be read from the ATUS database. In this example, the input SAS data set is named in the INSET=INSERIES option. To create the INSERIES data set, use the DATA step. In the DATA statement, the name of the input data set is specified as 'INSERIES'. Next, the length of the series ID is specified as 32 bytes prior to listing each series ID to be accessed. Each time series is listed on its own line, along with the OUTPUT statement. When the series IDs have been listed, the DATA step is ended with a RUN statement. The following SASEBLS LIBNAME statement specifies the libref (BLS), followed by the engine name (SASEBLS) and the physical path where the retrieved BLS data are to be stored. The OUTJSON= option names the file where the JSON data are stored. The output data set is created using the OUTJSON= option and placed in the folder that is specified in the SASEBLS LIBNAME statement. The INSET= option specifies the INSERIES data set for the list of series to retrieve using their IDs. In this example, four time series are requested.

The date range of the data starts with 2009, as specified by the STARTYEAR= option. The ENDYEAR= option specifies the last year, 2019, to include in the range of data to retrieve. The FREQ=ANNUAL (or FREQ=A) option specifies the selection of annual data. The ASPECTS=TRUE option is specified, and the data that are retrieved show the standard error, name_aspects, and the value, value_aspects, that are associated with each observation of each time series. The FORMAT= option specifies that the data are to be retrieved using the JSON format. Output 23.12.1 shows the data that are retrieved. Output 23.12.2 shows the catalog information for the retrieved data. Output 23.12.3 shows the aspects information for the retrieved data.

options validvarname=any;
libname blscat "%sysget(BLS)";     /* for Catalog data set*/

DATA inseries;
   length seriesid $ 32;
   seriesid = 'TUU10101AA01001181'; output;
   seriesid = 'TUU10101AA01001260'; output;
   seriesid = 'TUU20101AA01002999'; output;
   seriesid = 'TUU20101AA01003084'; output;
RUN;

title 'Retrieve American Time Use Survey Data';
libname bls sasebls "%sysget(BLS)"
   USER='XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX'
   SETNAME=ATUS
   INSET=inseries
   PAYPATH= "%sysget(BLS)payload"
   OUTJSON=blsex12
   STARTYEAR='2009'
   ENDYEAR='2019'
   FREQ=Annual
   ASPECTS=true
   CATALOG=true
   FORMAT=json;

data myTUS;
   set bls.blsex12;
run;

proc contents data=myTUS; run;
proc print data=myTUS; run;

The following statements print the catalog data shown in Output 23.12.2:

libname blscat "%sysget(BLS)";

data myCAT;
   set blscat.blsex12_catalog;
run;

proc print data=myCAT; run;

The following statements print the aspects data as shown in Output 23.12.3. Each time series has its own corresponding name aspects and value aspects time series. The first series, TUU10101AA01001181, has the corresponding name aspects time series TUU10101AA01001181_name_aspects, and it also has the corresponding value aspects time series TUU10101AA01001181_value_aspects. This naming convention, where the time series name also appears as a prefix in the name aspects and value aspects series names, is used for each of the retrieved series.

libname blscat "%sysget(BLS)";

data myASPECTS;
   set blscat.blsex12_data_aspects;
run;

proc print data=myASPECTS; run;