SASEBLS Interface Engine

This example shows how to retrieve data from the Weekly Hours and Earnings Survey, LE, and the Labor Force Statistics Survey (includes the national unemployment rate), LN, both from the Current Population Statistics program data. You can view these data by using the following URL:

https://www.bls.gov/cps/

INSERIES is an input SAS data set that lists the IDs of the time series to be retrieved from the Current Population Statistics database. In this example, the input SAS data set is named in the INSET=INSERIES option. To create the INSERIES data set, use the DATA step. In the DATA statement, the name of the input data set is specified as 'INSERIES'. Next, the length of the series ID is specified as 32 bytes prior to listing the ID of each series to be accessed. Each time series is listed on its own line, along with the OUTPUT statement. When the series IDs have been listed, the DATA step is ended with a RUN statement. The following SASEBLS LIBNAME statement specifies the libref (BLS), followed by the engine name (SASEBLS) and the physical path where the retrieved BLS data are to be stored. The OUTJSON= option names the file where the JSON data are stored. The output data set is created using the OUTJSON= option and placed in the folder that is specified in the SASEBLS LIBNAME statement. The INSET= option specifies the INSERIES data set for the list of series to retrieve using their IDs. In this example, four time series are requested, along with any calculations.

The date range of the data starts with 2021, as specified by the STARTYEAR= option. The ENDYEAR= option specifies the last year, 2022, to include in the range of data to retrieve. The FREQ=QUARTERLY option specifies the selection of quarterly data, but because the CALCULATIONS=TRUE option is specified, the retrieved data also include the net change calculation and percentage change calculation statistics. The FORMAT= option specifies that the data are to be retrieved using the JSON format. Output 23.7.1 shows the data that are retrieved. Output 23.7.2 shows the catalog information for the retrieved data.

options validvarname=any;
libname blscat "%sysget(BLS)";     /* for Catalog data set*/

DATA inseries;
   length seriesid $ 32;
   seriesid = 'LNS11000000Q'; output;
   seriesid = 'LNS11000012Q'; output;
   seriesid = 'LES1252881500'; output;
   seriesid = 'LES1252882800'; output;
RUN;

title 'Retrieve Labor Force Current Population Statistics Data';
libname bls sasebls "%sysget(BLS)"
   USER='XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX'
   SETNAME=CPS
   INSET=inseries
   PAYPATH= "%sysget(BLS)payload"
   OUTJSON=blsex07
   STARTYEAR='2021'
   ENDYEAR='2022'
   FREQ=Quarterly
   CALCULATIONS=true
   CATALOG=true
   FORMAT=json;

data myCPS;
   set bls.blsex07 ;
run;

proc contents data=myCPS; run;
proc print data=myCPS; run;

The following statements print the catalog information shown in Output 23.7.2:

libname blscat "%sysget(BLS)";     /* for Catalog data set*/

data myCAT;
   set blscat.blsex07_catalog;
run;

proc print data=blscat.blsex07_catalog; run;