The PHREG Procedure

(View the complete code for this example.)

This example illustrates using a piecewise exponential model in a Bayesian analysis. Consider the Rats data set in the section Getting Started: PHREG Procedure. In the following statements, PROC PHREG is used to carry out a Bayesian analysis for the piecewise exponential model. In the BAYES statement, the option PIECEWISE stipulates a piecewise exponential model, and PIECEWISE=HAZARD requests that the constant hazards be modeled in the original scale. By default, eight intervals of constant hazards are used, and the intervals are chosen such that each has roughly the same number of events.

data Rats;
   label Days  ='Days from Exposure to Death';
   input Days Status Group @@;
   datalines;
143 1 0   164 1 0   188 1 0   188 1 0
190 1 0   192 1 0   206 1 0   209 1 0
213 1 0   216 1 0   220 1 0   227 1 0
230 1 0   234 1 0   246 1 0   265 1 0
304 1 0   216 0 0   244 0 0   142 1 1
156 1 1   163 1 1   198 1 1   205 1 1
232 1 1   232 1 1   233 1 1   233 1 1
233 1 1   233 1 1   239 1 1   240 1 1
261 1 1   280 1 1   280 1 1   296 1 1
296 1 1   323 1 1   204 0 1   344 0 1
;

proc phreg data=Rats;
   model Days*Status(0)=Group;
   bayes seed=1 piecewise=hazard statistics=(summary interval)
         diagnostics=(autocorr geweke ess);
run;

The "Model Information" table in Output 91.14.1 shows that the piecewise exponential model is being used.

By default the time axis is partitioned into eight intervals of constant hazard. Output 91.14.2 details the number of events and observations in each interval. Note that the constant hazard parameters are named Lambda1,…, Lambda8. You can supply your own partition by using the INTERVALS= suboption within the PIECEWISE=HAZARD option.

The model parameters consist of the eight hazard parameters Lambda1, …, Lambda8, and the regression coefficient Group. The maximum likelihood estimates are displayed in Output 91.14.3. Again, these estimates are used as the starting values for simulation of the posterior distribution.

Without using the PRIOR= suboption within the PIECEWISE=HAZARD option to specify the prior of the hazard parameters, the default is to use the noninformative and improper prior displayed in Output 91.14.4.

The noninformative uniform prior is used for the regression coefficient Group (Output 91.14.5), as in the section Bayesian Analysis.

Summary statistics for all model parameters are shown in Output 91.14.6 and Output 91.14.7.

The requested diagnostics—namely, lag1, lag5, lag10, lag50 autocorrelations (Output 91.14.8), the Geweke diagnostics (Output 91.14.9), and the effective sample size diagnostics (Output 91.14.10)—show a good mixing of the Markov chain.

The piecewise exponential model is an alternative to the Cox model. Another alternative model is the proportional hazards spline model of Royston and Parmar (2002). You can use the SPLINE option in the BAYES statement to perform a Bayesian analysis of this model, as in the following statements:

proc phreg data=Rats;
   model Days*Status(0)=Group;
   bayes seed=1 spline statistics=(summary interval)
         diagnostics=(autocorr geweke ess);
run;