The GEE Procedure

(View the complete code for this example.)

Because the respiratory data in Example 44.1 are binary, you can use the alternating logistic regression (ALR) method and model associations by using the log odds ratios instead of working correlations. This example fits a "fully parameterized cluster" model for the log odds ratio. That is, there is a log odds ratio parameter for each unique pair of responses within clusters, and all clusters are parameterized identically. The following statements fit the same regression model for the mean as in Example 44.1 but use a regression model for the log odds ratios instead of a working correlation. LOGOR=FULLCLUST specifies a fully parameterized log odds ratio model.

proc gee data=Resp descend;
   class ID Treatment Center Sex Baseline;
   model Outcome=Treatment Center Sex Age Baseline / dist=bin;
   repeated  subject=ID(Center) / logor=fullclust;
run;

The results of fitting the model are displayed in Output 44.4.1.

The parameters Alpha1 through Alpha6 estimate the log odds ratio for each unique within-cluster pair. The correspondence between the log odds ratio parameters and within-cluster pairs is displayed in Output 44.4.2.

Model goodness-of-fit criteria are shown in Output 44.4.3.

The QIC for the ALR model shown in Output 44.4.3 is 511.86, whereas the QIC for the unstructured working correlation model shown in Output 44.1.3 is 512.34, indicating that the ALR model has a slightly better fit.

You can fit the same model by fully specifying the matrix; for the definition of the matrix, see the section Specifying Log Odds Ratio Models. The following statements create a data set that contains the full matrix:

data zin;
   keep id center z1-z6 y1 y2;
   array zin(6) z1-z6;
   set resp;
   by center id;
   if first.id
      then do;
      t = 0;
      do m = 1 to 4;
         do n = m+1 to 4;
            do j = 1 to 6;
               zin(j) = 0;
            end;
            y1 = m;
            y2 = n;
            t + 1;
            zin(t) = 1;
            output;
         end;
      end;
   end;
run;

proc print data=zin (obs=12);
run;

Output 44.4.4 displays the full matrix for the first two clusters. The matrix is identical for all clusters in this example.

The following statements fit the model for fully parameterized clusters by fully specifying the matrix. The results are identical to those shown previously.

proc gee data=Resp descend;
   class ID Treatment Center Sex Baseline;
   model Outcome=Treatment Center Sex Age Baseline / dist=bin;
   repeated  subject=ID(Center) / logor=zfull
                                  zdata=zin
                                  zrow =(z1-z6)
                                  ypair=(y1 y2);
run;