CSPATIALREG Procedure

This example uses two simulated data sets, SimData and SimW, to illustrate model fitting in PROC CSPATIALREG and to facilitate subsequent discussion.

The SimData data set contains 50 observations and five variables. The variable SID identifies each spatial unit in the data. The three explanatory variables are x1, x2, and x3. The dependent variable is y. The SimW data set defines the spatial contiguity for all 50 spatial units. The first column, SID, in the SimW data set identifies each spatial unit. The remaining entries in the SimW data set are binary and define whether two spatial units are neighbors. A value of 1 indicates that two spatial units are neighbors, and 0 indicates otherwise.

Summary statistics for all variables except SID in the SimData data set are computed by the following statements and presented in Output 13.2.1:

proc means data=mylib.SimData;
   var x1 x2 x3 y;
run;

The following statements fit a spatial autoregressive (SAR) model to the data by using three regressors, x1, x2, and x3:

/*-- SAR --*/
proc cspatialreg data=mylib.SimData Wmat=mylib.SimW;
  model y=x1-x3 / type=SAR;
  spatialid SID;
run;

The parameter estimates for this model are shown in Output 13.2.2.

To fit a spatial Durbin model (SDM) that includes exogenous interaction effects of x1, x2, and x3, submit the following statements:

/*-- SDM  --*/
proc cspatialreg data=mylib.SimData Wmat=mylib.SimW;
  model y=x1-x3/ type=SAR;
  spatialeffects x1-x3;
  spatialid SID;
run;

The parameter estimates for this model are shown in Output 13.2.3.

If you want to fit another type of model, you need to change the value of the TYPE= option in the MODEL statement. As an example, to fit a spatial error model (SEM) instead of a SAR model to the data, you can use the following statements:

/*-- SEM --*/
proc cspatialreg data=mylib.SimData Wmat=mylib.SimW;
  model y=x1-x3 / type=SEM;
  spatialid SID;
run;

The parameter estimates for this model are shown in Output 13.2.4.

The following statements fit a spatial autoregressive confused (SAC) model and spatial autoregressive moving average (SARMA) model to the data:

/*-- SAC --*/
proc cspatialreg data=mylib.SimData Wmat=mylib.SimW;
  model y=x1-x3 / type=SAC;
  spatialid SID;
run;

/*-- SARMA --*/
proc cspatialreg data=mylib.SimData Wmat=mylib.SimW;
  model y=x1-x3 / type=SARMA;
  spatialid SID;
run;

The parameter estimates for the SAC and SARMA models are shown in Output 13.2.5 and Output 13.2.6, respectively.