CQLIM Procedure

This example shows how to estimate a bivariate probit model by using a large data table.

The following DATA step generates a data set that contains 1 million observations from a bivariate probit model:

data bivariate_probit;
   call streaminit(19283);
   keep y1 y2 x1 x2;
   do i = 1 to 1000000;
      x1 = rand('NORMAL', 0, 1);
      x2 = rand('NORMAL', 0, 1);
      u1 = rand('NORMAL', 0, 1);
      u2 = rand('NORMAL', 0, 1);
      y1l = 1 + 2 * x1 + 3 * x2 + u1;
      y2l = 3 + 4 * x1 - 2 * x2 + u1 * 0.2 + u2;
      if y1l > 0 then y1 = 1;
      else            y1 = 0;
      if y2l > 0 then y2 = 1;
      else            y2 = 0;
      output;
   end;
run;

You can load the data set bivariate_probit into a data table in your session that is associated with the mylib libref. The DATA step assumes that your libref is named mylib, but you can substitute any appropriately defined libref.

data mylib.bivariate_probit;
   set bivariate_probit;
run;

The following statements estimate a bivariate probit model. Note that the INIT statement in the SAS program sets the initial values for some parameters in the optimization. The METHOD=QN option specifies the quasi-Newton optimization algorithm.

proc cqlim data = mylib.bivariate_probit method = qn;
   init y1.x1 = 2.8, y1.x2 = 2.1, _rho = 0.1;
   model y1 = x1 x2 / discrete;
   model y2 = x1 x2 / discrete;
run;

Output 12.2.1 shows the estimation results for the bivariate probit model. The "Discrete Response Profile" tables show the response profile for the variables and .