CPANEL Procedure

Cornwell and Trumbull (1994) examined data on crime rates from 90 counties in North Carolina and collected data each year from 1981 to 1987. The following statements create the Crime data table. These statements assume that your libref is named mylib, but you can substitute any appropriately defined libref.

data mylib.Crime;
   input county year west central urban d82 d83 d84 d85 d86 d87
         lcrmrte lprbarr lprbconv lprbpris lavgsen lpolpc
         ldensity ltaxpc lwcon lwtuc lwtrd lwfir lwser lwmfg
         lwfed lwsta lwloc lmix lpctymle lpctmin;
   label county    = 'county identifier'
         year      = '81 to 87'
         west      = '1 if in western N.C.'
         central   = '1 if in central N.C.'
         urban     = '1 if in SMSA'

   ... more lines ...   

The variables are too numerous to describe individually, but they are fully labeled in the regression output and are summarized as follows:

Cornwell and Trumbull (1994) fit a fixed-effects model for the log of crime rate, with the log-probability of arrest (LPrbArr), and the log of police per capita (LPolPC) among the regressors. They noted that these two regressors were endogenous because of the following causality loops:

To deal with the endogeneity, Cornwell and Trumbull (1994) fit a two-stage least squares (2SLS) model with county-level fixed effects, with two external instruments: LTaxPC (log tax revenue per capita) and LMix (log ratio of crimes that involve face-to-face contact). Their rationale for using these instruments is that counties with higher tax revenues have more police presence and that face-to-face crimes have a higher probability of arrest because victims could identify their offenders.

Baltagi (2006) proposed a similar 2SLS model, but with random effects instead of fixed effects for counties. The following statements recreate that estimation:

proc cpanel data =  mylib.crime;
   id county year;
   model lcrmrte = lprbarr lpolpc lprbconv lprbpris lavgsen ldensity
                   lwcon lwtuc lwtrd lwfir lwser lwmfg lwfed lwsta
                   lwloc lpctymle lpctmin west central urban
                   d82 d83 d84 d85 d86 d87 / ivranone;
   endogenous lprbarr lpolpc;
   instruments ltaxpc lmix;
run;

The results are shown in Figure 5. The output includes a "Structural Summary" table, which lists the endogenous variables and the instrumental variables. The list of instrumental variables includes both the specified external instruments (variables LTaxPC and LMix) and the exogenous regression variables.

Cornwell and Trumbull (1994) favored a fixed-effects approach because a Hausman specification test rejected the null hypothesis of random effects. Baltagi (2006) argued that the Hausman test used by Cornwell and Trumbull (1994) was inaccurate because it was based on standard methodology that did not account for endogeneity in the regressors.

Baltagi (2006) proposed a modified 2SLS Hausman test, and the results of that test are provided in the "Hausman Test For Random Effects" table in the output. The results favor the random-effects specification.

A higher probability of arrest is shown to diminish crime, and police presence increases the crime rate because more crimes are reported.

The following statements fit the model by two-step GMM with robust standard errors:

proc cpanel data =  mylib.crime;
   id county year;
   model lcrmrte = lprbarr lpolpc lprbconv lprbpris lavgsen ldensity
                   lwcon lwtuc lwtrd lwfir lwser lwmfg lwfed lwsta
                   lwloc lpctymle lpctmin west central urban
                   d82 d83 d84 d85 d86 d87 / ivranone gmm = twostep
                   robust;
   endogenous lprbarr lpolpc;
   instruments ltaxpc lmix;
run;

The results are shown in Output 11.4.1. The coefficients do not change much, but the standard errors are now more reliable. You can also obtain bias-corrected standard errors by using the BIASCORRECTED option according to the method of Windmeijer (2005).