Mixed Modeling Action Set

This section contains PROC CAS code.

Note: Input data must be accessible in your CAS session, either as a CAS table or as a transient-scope table. A CAS table has a two-level name: the first level is your CAS engine libref, and the second level is the table name. You refer to this table in the CAS procedure by specifying only the second level. For more information about two-level names, see Chapter 2, Shared Concepts. A transient-scope table is called directly from the action and exists in memory for the duration of the action. For more information about accessing data, see SAS Viya: System Programming Guide. For more information about PROC CAS and programming in CASL, see SAS Cloud Analytic Services: CASL Programmer’s Guide and SAS Cloud Analytic Services: CASL Reference.

This example demonstrates how you can perform a mixed model analysis of covariance when you have many groups. Suppose you are an educational researcher who studies how student scores on math tests change over time. Students are tested four times, and you want to estimate the overall rise or fall, accounting for correlation between test response behaviors of students in the same neighborhood and school. One way to model this correlation is by using a random-effects analysis of covariance, where in addition to having a student-specific quadratic mean response function, the scores for students from the same neighborhood and school are all assumed to share the same quadratic mean test response function whose parameters are random. The following statements simulate data that have this structure; these statements assume that your CAS engine libref is named mycas, but you can substitute any appropriately defined CAS engine libref.

data mycas.SchoolSample;
   do SchoolID = 1 to 1000;
      do nID = 1 to 50;
         Neighborhood = (SchoolID-1)*15 + nId;
         bInt   = 15*ranuni(1);
         bTime  = 15*ranuni(1);
         bTime2 =   ranuni(1);
         do sID = 1 to 2;
            do Time = 1 to 4;
               Math = bInt + bTime*Time + bTime2*Time*Time + rannor(2);
               output;
               end;
            end;
         end;
      end;
run;

These data comes from 1,000 schools and about 15,035 neighborhoods; neighborhoods are associated with more than one school and vice versa. There are 400,000 observations and 50,000 levels of the subject effect.

The following statements use the mixed action to fit a linear mixed model to these data and produce Output 14.1.1 through Output 14.1.4:

proc cas;
action mixed.mixed /
   table={name='SchoolSample'},
   class={{vars={'Neighborhood', 'SchoolID'}}},
   model={depVars={{name='Math'}},
          effects={{vars={'Time'}},
                   {vars={'Time','Time'},interaction='CROSS'}},
          printsol = TRUE},
   random={{noint=FALSE,
            effects={{vars={'Time'}},
                     {vars={'Time','Time'},interaction='CROSS'}},
            type='RANDOM',
            subject= {{vars={'Neighborhood','SchoolID'},interaction='CROSS'}},
            covType='UN',
            printsol=TRUE}};
run;

This model fits a quadratic mean response model with an unstructured covariance matrix to model the covariance between the random parameters of the response model. With 15,035 combinations of neighborhoods and schools, this model can be computationally daunting to fit, but the mixed action finishes quickly, by distributing the data and the likelihood computation for different subjects in a CAS computing environment.

Output 14.1.1 displays the "Model Information," "Optimization Information," "Class Level Information," "Number of Observations Information," and "Dimensions" tables.

Output 14.1.2 displays the convergence status and the "Covariance Parameter Estimation" table.

Output 14.1.3 displays the "Fit Statistics" table.

Output 14.1.4 displays the "Solution for Fixed Effects" table.

These estimates are very close to the quadratic coefficients that are used in the SAS DATA step, multiplied by 1/2, which is the expected value of a uniform random variable on [0,1].

s:loadtable{casLib="casuser", path="schoolSample.csv"}

s:loadactionset{actionset='mixed'}
res=s:mixed{
    table='schoolSample',
    class={ {vars={'Neighborhood','SchoolID'}}},
    model={ depVars={{name='Math'}},
            effects={ {vars={'Time'}},
                      {vars={'Time','Time'},interaction='CROSS'}},
            printsol = 'TRUE'},
    random={ {effects={{vars={'Time'}},
                       {vars={'Time','Time'},interaction='CROSS'}},
              noint='FALSE',
              subject={{vars={'Neighborhood','SchoolID'},interaction='CROSS'}},
              type='RANDOM',
              covType='UN',
              printsol='TRUE'}},
}

print(res.ModelInfo)
print(res.OptInfo)
print(res.ClassInfo)
print(res.NObs)
print(res.Dimensions)
print(res.ConvergenceStatus)
print(res.CovParms)
print(res.FitStatistics)
print(res.ParameterEstimates)

print(res)

s.upload_file('schoolSample.csv')

s.loadactionset(actionset='mixed')
res=s.mixed(
      table='schoolSample',
      classVars=['Neighborhood','SchoolID'],
      model={'depVars':'Math',
             'effects':['Time',
                        {'vars':['Time','Time'],'interact':'CROSS'}
                       ],
              'printsol':'TRUE'},
      random=[{'effects':['Time',
                          {'vars':['Time','Time'],'interact':'CROSS'}
                         ],
               'noint':'False',
               'subject':[{'vars':{'Neighborhood','SchoolID'},'interact':'CROSS'}],
               'type':'RANDOM',
               'covType':'UN',
               'printsol':'True'}
             ]
    )

print(res.ModelInfo)
print(res.OptInfo)
print(res.ClassInfo)
print(res.NObs)
print(res.Dimensions)
print(res.ConvergenceStatus)
print(res.CovParms)
print(res.FitStatistics)
print(res.ParameterEstimates)

print(res)