The HPCLUS Procedure

This example shows how to use the HPCLUS procedure to compute clusters of observations in a SAS data set.

Suppose you want to group the observations in inputData, in which the variables are raw measures on interval scales.

The following SAS DATA step creates the SAS data set inputData, which has four variables: the first two variables are the input variables among which x has missing values, the third variable is the frequency variable, and the last variable is an index variable.

data inputData;
   title 'Using PROC HPCLUS to Analyze Data';
   drop n;
   id=1;
   do n=1 to 1000;
      x=2*rannor(12345)+20;
      y=4*rannor(12345)+20;
      freq = 1;
      id = id + 1;
      output;
   end;
   do n=1 to 1000;
      x=3*rannor(12345)+10;
      y=5*rannor(12345)+10;
      freq=2;
     id = id + 1;
   output;
   end;
   do n=1 to 700;
     x=10*rannor(12345);
     y=10*rannor(12345);
     freq=1;
     id = id + 1;
     output;
   end;
	 do n=1 to 200;
     x=.;
     y=10*rannor(12345);
     freq=1;
     id = id + 1;
     output;
   end;
run;

The following statements run PROC HPCLUS and output the results to ODS tables:

proc hpclus data=inputData maxclusters=3;
   input x y;
   freq freq;
run;

Figure 1 shows the values of the parameters that are used in clustering. Because MAXCLUSTERS=3 and the number of clusters is not estimated by default, three clusters are generated. Figure 1 shows the number of clusters and default values for other options.

Figure 2 shows that the "Number of Observations Used" is less than “Number of Observations Read.” By default, the HPCLUS procedure ignores observations that have missing values, and it does not use them in cluster analysis. The two additional rows, "Sum of Frequencies Read" and “Sum of Frequencies Used,” are displayed when the FREQ statement is specified. They provide information about the frequency values that are read and used.

Figure 3 shows the statistics for each cluster. For each cluster, this table shows the number of observations; the maximum, minimum, and average distances from that cluster’s centroid to the observations in that cluster; the sum of squares error; and the standard deviation. In addition, Figure 3 displays information about the nearest cluster to that cluster and the distance between their centroids.

Figure 4 shows the sum of squares error (SSE) for each iteration.

Figure 5 and Figure 6 show the statistics for each variable in the INPUT statement. Figure 5 shows the variable statistics for all the observations in the input data set, and Figure 6 shows the variable statistics for the observations that belong to a specific cluster.