CNTSELECT Procedure

This example shows how to use the CNTSELECT procedure to estimate a zero-inflated Poisson model by using Bayesian methods, with user-specified priors. The following DATA step generates 1,000 replicates from the zero-inflated Poisson (ZIP) model. The model contains seven variables and three variables that correspond to the zero-inflated process.

data bayes_ex;
   call streaminit(12345);
   array vars x1-x7;
   array zero_vars z1-z3;
   array parms{7}  (.3 .4 .2 .4 -.3 -.5 -.3);
   array zero_parms{3} (-.6 .3 .2);
   intercept=0.5;
   group=1;
   z_intercept=-1;
   theta=0.5;
   do i=1 to 1000;
      sum_xb=0;
      sum_gz=0;
      if i>500 then do;
         intercept=2;
         group=2;
      end;
      do j=1 to 7;
         vars[j]=rand('NORMAL',0,1);
         sum_xb=sum_xb+parms[j]*vars[j];
      end;
      mu=exp(intercept+sum_xb);
      y_p=rand('POISSON', mu);
      do j=1 to 3;
         zero_vars[j]=rand('NORMAL',0,1);
         sum_gz = sum_gz+zero_parms[j]*zero_vars[j];
      end;
      z_gamma = z_intercept+sum_gz;
      pzero = cdf('LOGISTIC',z_gamma);
      cut=rand('UNIFORM');
      if cut<pzero then y_p=0;
      output;
   end;
   keep y_p group x1-x7 z1-z3;
run;

You can load the data set bayes_ex into a data table in your session that is associated with the mylib libref. The DATA step assumes that your libref is named mylib, but you can substitute any appropriately defined libref.

data mylib.bayes_ex;
   set bayes_ex;
run;

The following statements estimate a zero-inflated Poisson model via Bayesian analysis. Note that the BAYES statement controls the settings for the MCMC sampler and determines which Bayesian output to produce. The PRIOR statements set the prior distributions for the parameters.

proc cntselect data=mylib.bayes_ex dist=zip;
   class group;
   model y_p=group x1-x7;
   zeromodel y_p ~ z1-z3;
   bayes seed = 81239 nmc = 10000 sampler = rwm(ntu = 50) priorsummary(shownames);
   prior x1-x7 ~ normal(mean = 0, sd = 10);
   prior group_1 ~ normal(mean = 0, sd = 10, upper = 0);
   prior Intercept ~ normal(mean = 0, sd = 10);
   prior Inf_z1-Inf_z3 ~ normal(mean = 0, sd = 1);
   prior Inf_Intercept ~ normal(mean = 0, sd = 10);
run;

Output 10.2.1 shows the results for the zero-inflated Poisson model. The "Prior Summary" table shows detailed information about prior distributions for the parameters in the model. The "Posterior Summaries" table contains two point estimates of the parameters from the posterior samples: the posterior mean and the posterior median (50th percentile). The "MCMC Diagnostic Summaries" table contains basic convergence diagnostics to check whether the Markov chain has converged and whether the sample size is sufficient.