The SASEBLS Interface Engine

This example shows how to retrieve data from the Current Employment Statistics Survey (CE). You can view these data by using the following URL:

https://www.bls.gov/ces/data/

INSERIES is an input SAS data set that lists the time series IDs to be read from the Current Employment Statistics (CES) database. In this example, the input SAS data set is named in the INSET=INSERIES option. To create the INSERIES data set, use the DATA step. In the DATA statement, the name of the input data set is specified as 'INSERIES'. Next, the length of the series ID is specified as 32 bytes prior to listing each series ID to be accessed. Each time series is listed on its own line, along with the OUTPUT statement. When the series IDs have been listed, the DATA step is ended with a RUN statement. The following SASEBLS LIBNAME statement specifies the libref (BLS), followed by the engine name (SASEBLS) and the physical path where the retrieved BLS data are to be stored. The OUTJSON= option names the file where the JSON data are stored. The output data set is created using the OUTJSON= option and placed in the folder that is specified in the SASEBLS LIBNAME statement. The INSET= option specifies the INSERIES data set for the list of series IDs to retrieve. In this example, two time series, CES0000000001 and CEU0500000001, are requested, along with any calculations. Both time series have 1-month, 3-month, 6-month, and 12-month net and percentage changes.

The date range of the data starts with 2003, as specified by the STARTYEAR= option. The ENDYEAR= option specifies the last year, 2004, to include in the range of data to retrieve. The FREQ=MONTH option specifies the selection of monthly data, but because the CALCULATIONS=TRUE option is specified, the retrieved data also include the net change calculation and percentage change calculation statistics. Because the ANNUALAVERAGE=TRUE option is specified, the output should include the annual average M13 data, but in this example only one of the requested time series, CEU0500000001, has data for the M13 frequency. The FORMAT= option specifies that the data are to be retrieved using the JSON format. Output 20.5.1 shows the data that are retrieved.

options validvarname=any;

DATA inseries;
   length seriesid $ 32;
   seriesid = 'CES0000000001'; output; /* All employees */
   seriesid = 'CEU0500000001'; output;

RUN;

title 'Retrieve Current Employment Statistics Data';
libname bls sasebls "%sysget(BLS)"
   USER='XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX'
   SETNAME=CES
   INSET=inseries
   PAYPATH= "%sysget(BLS)payload"
   OUTJSON=blsex05
   STARTYEAR='2003'
   ENDYEAR='2004'
   FREQ=Month
   CALCULATIONS=true
   ANNUALAVERAGE=true
   CATALOG=true
   FORMAT=json;

data myCES;
   set bls.blsex05 ;
run;

proc print data=myCES; run;

The following code prints the catalog information:

libname blscat "%sysget(BLS)";

data myCAT;
   set blscat.blsex05_catalog;
run;

proc print data=myCAT; run;