The MKTATTRIBUTION Procedure

This section provides an example of the model that the MKTATTRIBUTION procedure supports.

The following statements read a data table that contains records of 2 million customer visits. The table has four columns: sec is the number to identify the customers, time is the time when the customer visits, c is a nonnegative integer variable that is converted from the channel variable and is to be used in the model, and channel is the channel that the customer visits at time t.

data marketData;
   format time DATETIME.;
   input sec  time:ANYDTDTM40.  c channel & $ 15.  ;
datalines ;
1   24MAY18:00:00:00    1   Direct Mail
1   05JUN18:23:25:55    4   email
1   05JUN18:23:26:36    0   conversion
2   13JUN19:18:05:25    11  social
2   26OCT19:03:44:08    4   email
3   22AUG19:13:25:49    7   paid social
4   28JUL19:00:52:21    7   paid social

   ... more lines ...   

1169566 15JUN18:11:18:33    5   organic
1169567 05MAY18:00:00:00    1   Direct Mail
1169567 03APR20:05:40:37    5   organic
1169567 03APR20:12:02:20    0   conversion
1169568 07SEP19:21:50:07    7   paid social
1169569 04MAY19:15:44:22    5   organic
1169570 14AUG18:15:14:56    11  social
1169570 21OCT19:00:00:00    1   Direct Mail
1169571 15MAY19:19:32:36    7   paid social
;

The following statements create the table (Figure 13) to show the one-to-one relationship of channel to c:

data channel;
  set marketData(keep=c channel);
run;
proc sort data=channel
  dupout=channel_NoDupkey nodupkey;
  by c;
run;
proc print data=channel noobs; var c channel; run;

In addition to the conversion, which equals 0, in the c variable, there are 13 distinctive channels shown in Figure 13.

The following statements estimate the Markov attribution model that has 13 channels:

proc sort data=marketData out=marketData nodupkey;
   by sec time;
run;
data mycas.marketData2;
   set marketData;
run;
proc mktattribution data=mycas.marketData2;
   id section=sec time=time;
   model c / nchannel=13;
   output outremoval=mycas.rm outcontribution=mycas.contribution outtpm=mycas.tpm ;
run;

The model information and number of observations are shown in Figure 14.

The estimates of the initial state probability vector are shown in Figure 15.

The estimated transition probability matrix are shown in Figure 16.

The conversion rates are shown in Figure 17.

The removal effects are shown in Figure 18.

The removal effect of a channel is the decrease in the probability of overall conversion if the channel were removed. In Figure 18, you see that channel 5 (organic) leads to the greatest decrease in the probability of conversion if it is missing.

The contributions are just normalized removal effects to indicate each channel’s contribution to the conversion. The contributions of the Markov attribution model and the other three heuristic attribution models are shown side by side in Figure 19. The last-touch model does not place as much value on channel 1 (direct mail) as other methods do, but it attributes the most value to channel 5 (organic). The first-touch model does not value channel 4 (email) as much as other methods do, but it attributes the most value to channel 1 (direct mail). The Markov and linear attribution models have similar attribution values for most of the channels, except that there is a 9% difference between the two models on the contribution of channel 1 (direct mail). The position-based model and time-decay model both attribute less credit to channel 4 (email), which is the third most important channel according to the Markov model. The reason might be that the email channel always appears in the middle of the customer journey.