options cashost="cloud.example.com" casport=5570;         /*1*/ 
cas casauto;
                                                          /*2*/ 
libname mytdlib teradata server="myserver" user=myuserid password=mypassword database=mydb;

proc delete data=mytdlib.simple1; run;                    /*3*/
data mytdlib.simple1;
   id = 1;
   x = 1;
run;
 
proc cas;                                                 /*4*/
   loadactionset "modelPublishing";
   action publishModelExternal submit / 
      modelName="tdmodel1"
      externalOptions={
          extType="teradata", server="myserver", 
          username="myuserid", password="mypassword",
          modelTable="sas_model_table"}
      program="data sasep.out / overwrite=yes; 
         method run(); 
            set sasep.in; 
            output; 
          end; 
      enddata;"   ;
run;
quit;

proc cas                                                  /*5*/;
   loadactionset "modelPublishing";
   action runModelExternal submit / 
      modelName="tdmodel1"
      externalOptions={
          extType="teradata", server="myserver", 
          username="myuserid", password="mypassword", 
          database="mydb", 
          modelTable="sas_model_table", 
          inTable="simple1",
          outTable="outdata",
          outKey="id"
      }
   ;
run;
quit;