Network Action Set

This section contains PROC CAS code.

Note: Input data must be accessible in your CAS session, either as a CAS table or as a transient-scope table. A CAS table has a two-level name: the first level is your CAS engine libref, and the second level is the table name. You refer to this table in the CAS procedure by specifying only the second level. For more information about two-level names, see Chapter 2, Shared Concepts (SAS Visual Data Mining and Machine Learning: Procedures). A transient-scope table is called directly from the action and exists in memory for the duration of the action. For more information about accessing data, see SAS Viya: System Programming Guide. For more information about PROC CAS and programming in CASL, see SAS Cloud Analytic Services: CASL Programmer’s Guide and SAS Cloud Analytic Services: CASL Reference.

This example illustrates the use of the community action on the undirected graph G shown in Figure 4.

Figure 4: An Undirected Graph G

The undirected graph G can be represented by the following links data set, LinkSetIn:

data LinkSetIn;
   input from $ to $ @@;
   datalines;
A B  A F  A G  B C  B D
B E  C D  E F  G I  G H
H I
;

The following DATA step loads the LinkSetIn data set into a CAS data table named mycas.LinkSetIn. These statements assume that the CAS engine libref is named mycas, but you can substitute any appropriately defined CAS engine libref.

data mycas.LinkSetIn;
   set LinkSetIn;
run;

The following statements perform community detection and output the results in the specified data tables:

proc cas;
   loadactionset "network";
   action network.community result=r status=s /
      indexOffset    = 1
      links          = {name = "LinkSetIn"}
      outNodes       = {name = "NodeSetOut", replace=true}
      outLevel       = {name = "CommLevelOut", replace=true}
      outCommunity   = {name = "CommOut", replace=true}
      outOverlap     = {name = "CommOverlapOut", replace=true}
      outCommLinks   = {name = "CommLinksOut", replace=true}
      resolutionList = {1.0, 0.5};
   run;
   print r.ProblemSummary; run;
   print r.SolutionSummary; run;
   action table.fetch / table = "NodeSetOut"; run;
   action table.fetch / table = "CommLevelOut" sortBy = "level"; run;
   action table.fetch / table = "CommOut" sortBy = {"community","level"}; run;
   action table.fetch / table = "CommOverlapOut" sortBy = "community"; run;
   action table.fetch / table = "CommLinksOut" sortBy = "level"; run;
quit;

The problem summary output from this action is shown in Output 22.4.1.

The solution summary output from this action is shown in Output 22.4.2.

The output data table NodeSetOut contains the community identifier of each node, as shown in Output 22.4.3.

The output data table CommLevelOut contains summary information at each resolution level, as shown in Output 22.4.4.

The output data table CommOut contains properties about each community, as shown in Output 22.4.5.

The output data table CommOverlapOut contains community overlap information, as shown in Output 22.4.6.

The output data table CommLinksOut describes how the communities are connected, as shown in Output 22.4.7.