UCM Procedure

The series in this example is studied in detail in Bloomfield (2000). This series consists of brightness measurements (magnitude) of a variable star taken at midnight for 600 consecutive days. The data can be downloaded from a time series archive maintained by the University of York, England (http://www.york.ac.uk/depts/maths/data/ts/welcome.htm (series number 26)). The following DATA step statements read the data in a SAS data set:

data star;
   input magnitude @@;
   day = _n_;
   format day best4.;
datalines;
  25  28  31  32  33  33  32  31  28   25   22   18
  14  10   7   4   2   0   0   0   2    4    8   11
  15  19  23  26  29  32  33  34  33   32   30   27
  24  20  17  13  10   7   5   3   3    3    4    5
   7  10  13  16  19  22  24  26  27   28   29   28

   ... more lines ...   

The following statements use the TIMESERIES procedure to get a timeseries plot of the series (see Output 30.2.1):

proc timeseries data=star plot=series;
   var magnitude;
run;

Output 30.2.1: Plot of Star Brightness on Successive Days

The plot clearly shows the cyclic nature of the series. Bloomfield shows that the series is very well explained by a model that includes two deterministic cycles that have periods 29.0003 and 24.0001 days, a constant term, and a simple error term. He also mentions the difficulty involved in estimating the periods from the data (Bloomfield 2000, Chapter 3). In his case the cycle periods are estimated by least squares, and the sum of squares surface has multiple local optima and ridges. The following statements show how to use the UCM procedure to fit this two-cycle model to the series. The constant term in the model is specified by holding the variance parameter of the level component to 0.

/* Load data into mylib */
data mylib.star;
   set star;
run;

proc ucm data= mylib.star;
   id day interval=obs;
   model magnitude;
   irregular;
   level var=0 noest;
   cycle;
   cycle;
   estimate;
run;

The final parameter estimates and the goodness-of-fit statistics are shown in Output 30.2.2 and Output 30.2.3, respectively. The model fit appears to be good.

A summary of the cycles in the model is given in Output 30.2.4.

Note that the estimated periods are the same as in Bloomfield’s model, the damping factors are nearly equal to 1.0, and the disturbance variances are very close to 0, implying persistent deterministic cycles. In fact, this model is identical to Bloomfield’s model.

Finally, Output 30.2.5 shows the likely outlying observations that do not conform to the fitted model. The first outlier in this table, day 301, is also flagged by Bloomfield (according to his zero-based index system, it is day 300).