DEEPCAUSAL Procedure

This example illustrates how a music subscription service from an online media company can offer targeted discounts through a personalized pricing plan based on many features that it observes about its customers to encourage them to buy more songs or beco me members. The main goal is to construct a policy that raises demand enough to boost overall revenue despite decreasing the price for some customers.

The data set is provided by the Microsoft research project ALICE and is available at https://msalicedatapublic.z5.web.core.windows.net/datasets/Pricing/pricing_sample.csv. The data set has 10,000 simulated observations that represent customers’ personal characteristics, such as age and log income, and online behavior history, such as previous purchase and previous online time per week. The treatment variable, t, is a binary variable that indicates whether or not a discount is applied. This variable is generated according to the values that the variable price takes in the data set. The value of t is 0 if the value of price is 1, indicating that no discount is given, and the value of t is 1 if the value of price is less than 1, indicating that a discount is applied. The outcome variable, revenue, is calculated by multiplying the number of songs purchased during the discount season by the price paid for the songs. Table 3 shows the names of the variables that are used in the model, their types, and their definitions. The type can be T (treatment), Y (outcome), (a covariate in the propensity score model), and/or (a covariate in the outcome model).

Table 3: Model Variables

Name	Type	Details
account_age	,	User’s account age
age	,	User’s age
avg_hours	,	Average number of hours user was online per week in the past
days_visited	,	Average number of days user visited website per week in the past
friend_count	,	Number of friends user connected to in account
has_membership	,	Whether user has membership
is_US	,	Whether user accesses website from US
songs_purchased	,	Average number of songs user purchased per week in the past
income	,	User’s income
t	T	Whether a discount is applied
revenue	Y	Number of songs purchased during discount season times price paid

Assuming that you have downloaded the data set pricing_sample in your session that is associated with the mylib libref, the following statements create an ID variable that has a unique value for each observation, the treatment variable (t), and the outcome variable (revenue) in the data table new_pricing_sample:

data mylib.new_pricing_sample;
   set mylib.pricing_sample;
       id = put(_threadid_,8.) || '_' || Put(_n_,8.); * ID variable;
       if price<1 then t=1; else t=0; * treatment variable;
       revenue=price*demand; * outcome variable;
run;

The first step in policy evaluation and policy optimization is to estimate the effect of the treatment and to save to a specified output data table the details of the estimation, including , , , the residual, and the influence functions for each unit. You can do this by using the following statements:

 /*--- Estimate the treatment effect and save the estimation details ---*/
 proc deepcausal data=mylib.new_pricing_sample;
    id id;
    psmodel t = account_age age avg_hours days_visited friends_count
                has_membership is_US songs_purchased income /
                dnn=(nodes=(32 32 32 32)
                train=(optimizer=(miniBatchSize=500 regL1=0.0001 maxEpochs=32000
                algorithm=adam) nthreads=20 seed=12345 recordseed=67890));
    model revenue = account_age age avg_hours days_visited friends_count
                    has_membership is_US songs_purchased income /
                    dnn=(nodes=(32 32 32 32)
                    train=(optimizer=(miniBatchSize=500 regL1=0.001 maxEpochs=32000
                    algorithm=adam) nthreads=20 seed=12345 recordseed=67890));
    infer out=mylib.oest outdetails=mylib.odetails;
 run;

For this example, the same covariates are used in both the propensity score mode and the outcome model. The model estimation details are saved in the output data table odetails.

The estimation results are shown in Output 15.2.1. The estimate of the average treatment effect, ATE, is negative and statistically significant, suggesting that the discount, on average, causes revenue that is generated by the whole population to decrease. However, the effect of the discount on the revenue among the customers who received a discount, which is measured by the parameter ATT (average treatment effect on the treated), is considerably different from the ATE estimate. It might suggest that identifying the characteristics of customers to whom the discount matters would help construct the optimum policy so that it uses the fewest resources and earns the most profit.

In policy optimization, the goal is to maximize the expected utility of a policy. For the definition of the expected utility function and how it is estimated, as well as details such as the definition of a policy rule, see the section Policy Evaluation and Comparison. In this example, because a positive treatment effect is preferred, anyone whose value is positive should be given the treatment (that is, a discount). This function is sometimes referred to as the individual treatment effect (ITE).

The variable _beta_ in the data table odetails that is obtained during the previous estimation contains the estimated values for this function for each individual. You can construct an optimal policy by offering a discount to individuals whose _beta_ value is positive. For comparison, the following DATA steps create the optimal policy, s2, along with the other policies: s0, offer n o one a discount; and s1, offer everyone a discount.

 data mylib.discountPolicy;
    set mylib.odetails;
    s0 = 0; * treat none;
    s1 = 1; * treat all;
    s2 = _beta_>=0; * treat only individuals whose ITEs are positive;
    keep id t account_age age avg_hours days_visited
         friends_count has_membership is_US songs_purchased
         income revenue s0 s1 s2;
 run;

You can do policy evaluation by specifying the POLICY= option in the INFER statement and do policy comparison by specifying the POLICYCOMPARISON= option in the same statement. The following statements estimate the model and do policy evaluation and comparison:

 /*--- Policy evaluation and comparison ---*/
 proc deepcausal data=mylib.discountPolicy;
    id id;
    psmodel t = account_age age avg_hours days_visited friends_count
                has_membership is_US songs_purchased income /
                dnn=(nodes=(32 32 32 32)
                train=(optimizer=(miniBatchSize=500 regL1=0.0001
                maxEpochs=32000 algorithm=adam) nthreads=20
                seed=12345 recordseed=67890));
    model revenue = account_age age avg_hours days_visited friends_count
                    has_membership is_US songs_purchased income /
                    dnn=(nodes=(32 32 32 32)
                    train=(optimizer=(miniBatchSize=500 regL1=0.001
                    maxEpochs=32000 algorithm=adam) nthreads=20
                    seed=12345 recordseed=67890));
    infer policy=(t s0 s1 s2) policyComparison=(base=(t)
          compare=(s0 s1 s2))
          out=mylib.oest2 outdetails=mylib.odetails2;
 run;

The option POLICY=(t s0 s1 s2) requests that the policy evaluation be done for the initial discount policy (t), the policy of giving no one a discount (s0), the policy of giving everyone a discount (s1), and the personalized discount policy of giving a discount only to those whose _beta_ value is positive (s2). The suboption COMPARE=(s0 s1 s2) in the POLICYCOMPARISON= option indicates that the policies s0, s1, and s2 are to be compared to the base policy, t, which is specified by the suboption BASE=(t), also in the POLICYCOMPARISON= option.

The policy evaluation results are shown in Output 15.2.2.

The optimal policy, s2, indeed has the highest estimate. When the discount is given to customers whose ITE is positive, the average outcome, which in this example is the revenue for each person, is higher than the average outcome that is obtained by the base policy. This is the largest revenue that is generated, and it is generated by the personalized discount policy.

Output 15.2.3 shows the output for the policy comparison. Negative values indicate that the corresponding discount policy is worse than the base policy, and positive values indicate that the corresponding discount policy is better than the base policy. As expected, s2, giving the discount to the right person, produces the best results.