Network Optimization Action Set

This section contains PROC CAS code.

Note: Input data must be accessible in your CAS session, either as a CAS table or as a transient-scope table. A CAS table has a two-level name: the first level is your CAS engine libref, and the second level is the table name. You refer to this table in the CAS procedure by specifying only the second level. For more information about two-level names, see Chapter 1, Introduction (SAS Optimization: The OPTNETWORK Procedure). A transient-scope table is called directly from the action and exists in memory for the duration of the action. For more information about accessing data, see SAS Viya: System Programming Guide. For more information about PROC CAS and programming in CASL, see SAS Cloud Analytic Services: CASL Programmer’s Guide and SAS Cloud Analytic Services: CASL Reference.

As an example, consider the weighted undirected graph in Figure 12.

Figure 12: An Undirected Graph

The links data set can be represented as follows:

data LinkSetIn;
   input from to weight @@;
   datalines;
1 2 2  1 5 3  2 3 3  2 5 2  2 6 2
3 4 4  3 7 2  4 7 2  4 8 2  5 6 3
6 7 1  7 8 3
;

The following DATA step loads the LinkSetIn data set into a CAS data table named mylib.LinkSetIn. These statements assume that the CAS engine libref is named mylib, but you can substitute any appropriately defined CAS engine libref.

data mylib.LinkSetIn;
   set LinkSetIn;
run;

The following statements calculate minimum cuts in the graph and output the results in the data tables MinCutCutSets and MinCutPartitions:

proc cas;
   loadactionset "optNetwork";
   action optNetwork.minCut result=r status=s /
      links         = {name = "LinkSetIn"}
      indexOffset   = 1
      maxCuts       = 3
      outPartitions = {name = "Partitions", replace = true}
      outCutSets    = {name = "CutSets", replace = true};
   run;
   print r.ProblemSummary; run;
   print r.SolutionSummary; run;
   action table.fetch / table = "Partitions" sortBy = "cut"; run;
   action table.fetch / table = "CutSets" sortBy = "cut"; run;
quit;

The problem summary output from this action is shown in Output 2.10.1.

The solution summary output from this action is shown in Output 2.10.2.

The output data table Partitions now contains the partition of the nodes for each cut, shown in Output 2.10.3.

The output data table mycas.CutSets contains the links in the cut sets for each cut. This data table is shown in Output 2.10.4.