Univariate Time Series Analysis Action Set

This section contains PROC CAS code.

Note: Input data must be accessible in your CAS session, either as a CAS table or as a transient-scope table. A CAS table has a two-level name: the first level is your CAS engine libref, and the second level is the table name. You refer to this table in the CAS procedure by specifying only the second level. For more information about two-level names, see Chapter 4, Shared Concepts (SAS Econometrics: Econometrics Procedures). A transient-scope table is called directly from the action and exists in memory for the duration of the action. For more information about accessing data, see SAS Viya: System Programming Guide. For more information about PROC CAS and programming in CASL, see SAS Cloud Analytic Services: CASL Programmer’s Guide and SAS Cloud Analytic Services: CASL Reference.

This example illustrates how you can use the arima action to model and forecast the airline passengers time series data.

The following DATA step creates the data table mycas.air in your CAS session from data that were recorded monthly. This DATA step assumes that your CAS engine libref is named mycas, but you can substitute any appropriately defined CAS engine libref.

data mycas.myair;
   set sashelp.air;
   AIR2 = air*air;
run;

The data table, mycas.myair, contains a variable, date (which represents time) and two variables named air and air2 (which represent the monthly number of passengers and their square, respectively). Each value of the date variable is recorded in ascending order.

The following PROC CAS statements use the arima action in the uniTimeSeries action set to specify an ARIMA model without a mean term to the logarithms of the airline passenger numbers, and an ARIMA model without a mean term to the squared airline passenger numbers:

proc cas;
   uniTimeSeries.arima /
      table={name='MYAIR'},
      timeId={name='DATE'},
      interval='MONTH',
      outEst={name='ARIEST', replace=true},
      outFor={name='ARIFOR', replace=true},
      series={{name='AIR',
               model={{estimate={q={{factor={1}}, {factor={12}}},
                                 method='ML', diff={1, 12},
                                 noint=true, transform='log'},
                       forecast={{lead=4}}}}
              },
              {name='AIR2',
               model={{estimate={p={{factor=1}},
                                 method='ML', noint=true,
                                 diff={1}, transform='log'},
                       forecast={{lead=6}}}}
               }
             };
   run;
   table.fetch /
      table = {name='ARIFOR',
         where='date>=''01SEP1960''d'};
   run;
 quit;

The table parameter names the input data table to be analyzed. The timeId parameter specifies that the Date variable contains time ID values. The interval parameter specifies a monthly interval at which to accumulate the time series vectors. The outEst parameter specifies the table in which to store the parameter estimates and their standard errors. The outFor parameter specifies the table in which to store the forecasts for the accumulated time series variables.

The series parameter list contains the name parameter (which names the series you want to analyze) and the model parameter list (which the specifies the types of inference tasks you want to perform).

Each model parameter list contains estimate and forecast parameter lists:

The arima action saves the parameter estimates and the forecasts to output tables whose names are specified in the outEst and outFor parameters. Output 21.1.1 shows a selected part of the ARIFOR table, which is requested in the outFor parameter.