ANYALNUM Function

Searches a character string for an alphanumeric character, and returns the first position at which the character is found.

Category:	Character
Restriction:	This function is assigned an I18N Level 1 status. If possible, avoid I18N Level 1 functions if you are using a non-English language. Under certain circumstances, the I18N Level 1 functions might not work correctly with Double-Byte Character Set (DBCS) or Multi-Byte Character Set (MBCS) encodings. For more information, see Internationalization Compatibility.
Note:	This function supports the VARCHAR type.

Table of Contents

Syntax

ANYALNUM(string <,start>)

Required Argument

string

specifies a character constant, variable, or expression to search.

Optional Argument

start

is an optional integer that specifies the position at which the search should start and the direction in which to search.

Details

The results of the ANYALNUM function depend directly on the translation table that is in effect (see TRANTAB= System Option in SAS National Language Support (NLS) Reference for SAS Viya Workbench) and indirectly on the ENCODING and LOCALE system options.

The ANYALNUM function searches a string for the first occurrence of any character that is a digit or an uppercase or lowercase letter. If such a character is found, ANYALNUM returns the position in the string of that character. If no such character is found, ANYALNUM returns a value of 0.

If you use only one argument, or if the second argument has a missing value, ANYALNUM begins the search at the beginning of the string. If you use two arguments, the absolute value of the second argument, start, specifies the position at which to begin the search. The direction in which to search is determined in one of these ways:

If the value of start is positive, the search proceeds to the right.
If the value of start is negative, the search proceeds to the left.
If the value of start is less than the negative length of the string, the search begins at the end of the string.

ANYALNUM returns a value of 0 when one of these conditions is true:

The character that you are searching for is not found.
The value of start is greater than the length of the string.
The value of start=0.

Comparisons

The ANYALNUM function searches a character string for an alphanumeric character. The NOTALNUM function searches a character string for a nonalphanumeric character.

Examples

Example 1: Scanning a String from Left to Right

This example uses the ANYALNUM function to search a string from left to right for alphanumeric characters.

data _null_;
   string='Next = Last + 1;';
   j=0;
   do until(j=0);
      j=anyalnum(string, j+1);
      if j=0 then put +3 "That's all";
      else do;
         c=substr(string, j, 1);
         put +3 j= c=;
      end;
   end;
run;

data _null_;
   string='Next = Last + 1;';
   j=0;
   do until(j=0);
      j=anyalnum(string, j+1);
      if j=0 then put +3 "That's all";
      else do;
         c=substr(string, j, 1);
         put +3 j= c=;
      end;
   end;
run;

SAS writes the following results to the log:

   j=1 c=N
   j=2 c=e
   j=3 c=x
   j=4 c=t
   j=8 c=L
   j=9 c=a
   j=10 c=s
   j=11 c=t
   j=15 c=1
   That's all

Example 2: Scanning a String from Right to Left

This example uses the ANYALNUM function to search a string from right to left for alphanumeric characters.

data _null_;
   string='Next = Last + 1;';
   j=999999;
   do until(j=0);
      j=anyalnum(string, 1-j);
      if j=0 then put +3 "That's all";
      else do;
         c=substr(string, j, 1);
         put +3 j= c=;
      end;
   end;
run;

data _null_;
   string='Next = Last + 1;';
   j=999999;
   do until(j=0);
      j=anyalnum(string, 1-j);
      if j=0 then put +3 "That's all";
      else do;
         c=substr(string, j, 1);
         put +3 j= c=;
      end;
   end;
run;