RECENGINE Procedure

This example shows how to use PROC RECENGINE to train a k-nearest-neighbors model on an explicit feedback data set, the MovieLens data set. The MovieLens data set was developed by the GroupLens project at the University of Minnesota and is available at http://grouplens.org/datasets/movielens . This example uses the MovieLens 1M version. You can download the compressed archive file from the website at http://files.grouplens.org/datasets/movielens/ml-1m.zip and use any third-party unzip tool to extract all the files in the archive to the destination directory of your choice.^[7] The file that contains the ratings is ratings.dat. The data set consists of movie ratings that are provided by a collection of users. For each observation, a user (indicated by the user ID column) has provided a rating from 1 to 5, as indicated by the rating column for a movie (indicated by the item ID column). The data set includes 1,000,209 rating events (user feedback). The following DATA step loads the data table from the directory into your session:

   data mylib.movieRatings;
      infile 'ratings.dat' DLMSTR = '::';
      input userid itemid rating timestamp;
   run;

The following statements use the KNN method that is implemented in PROC RECENGINE to train a k-nearest-neighbors model on the mylib.movieRatings data:

proc recengine data=mylib.movieRatings method =KNN outModel=mylib.nearestNeighbors;
     input     rating / level=interval;
     input     userid itemid / level=nominal;
     userid    userid;
     itemid    itemid;
     knn       k=5 distanceMetric=cosine outSimilarity=mylib.nearestNeighborValues;
     target    rating;
     savestate rstore=mylib.astoreModel;
run;

When the training is completed, PROC RECENGINE produces three output data tables: nearestNeighbors, nearestNeighborValues, and astoreModel. The nearestNeighbors table contains the nearest neighbors for each item; the nearestNeighborValues table contains the similarity scores for each item’s nearest neighbors; and the astoreModel table contains the nearest neighbors, similarity scores, and training data.

The following statements print the nearest neighbors of the first 10 items in the nearestNeighbors table. The results are shown in Output 28.2.1.

   proc print data=mylib.nearestNeighbors(obs=10);
   run;

The following statements print the nearest-neighbor similarity scores of the first 10 items in the nearestNeighborValues table. The results are shown in Output 28.2.2.

   proc print data=mylib.nearestNeighborValues(obs=10);
   run;

The following two code blocks show how to find the top five items for a sample user, whose user ID is 6040, by using the built-in analytic store scoring function. First, you create the scoring data table that includes the user ID of interest:

      data mylib.user6040;
      input   userid;
      datalines;
      6040
      ;
      run;

Next, you use the ASTORE procedure to score the binary-format output data table astoreModel for this user. In this scoring example, the following parameters are specified in SETOPTION statements:

   proc astore;
      setoption REC_TOP_N            5;
      setoption AGGREGATION_METHOD   0;
      setoption REC_ITEM_FILTER      1;
      score data=mylib.user6040 rstore=mylib.astoreModel out=mylib.rankedItemsKnn;
      run;
   quit;

The following statements print the five most recommended items for user 6040. The results are shown in Output 28.2.3.

   proc print data=mylib.rankedItemsKnn;
   run;