The MIANALYZE Procedure

(View the complete code for this example.)

This example creates data sets that contains parameter estimates and corresponding matrices computed by a general linear model analysis for a set of imputed data sets. These estimates are then combined to generate valid statistical inferences about the model parameters.

The following statements use PROC GLM to generate the parameter estimates and matrix for each imputed data set:

ods select none;
proc glm data=outmi;
   model Oxygen= RunTime RunPulse/inverse;
   by _Imputation_;
   ods output ParameterEstimates=glmparms
              InvXPX=glmxpxi;
quit;
ods select all;

Because of the ODS SELECT statements, no output is displayed. The following statements display (in Output 77.6.1) the output parameter estimates and standard errors from PROC GLM for the first two imputed data sets:

proc print data=glmparms (obs=6);
   var _Imputation_ Parameter Estimate StdErr;
   title 'GLM Model Coefficients (First Two Imputations)';
run;

The following statements display (in Output 77.6.2) matrices from PROC GLM for the first two imputed data sets:

proc print data=glmxpxi (obs=8);
   var _Imputation_ Parameter Intercept RunTime RunPulse;
   title 'GLM X''X Inverse Matrices (First Two Imputations)';
run;

The standard errors for the estimates in the output Glmparms data set are needed to create the covariance matrix from the matrix. The following statements use the MIANALYZE procedure with input PARMS= and XPXI= data sets to produce the same results as displayed in Output 77.3.2 and Output 77.3.3 in Example 77.3:

proc mianalyze parms=glmparms xpxi=glmxpxi edf=28;
   modeleffects Intercept RunTime RunPulse;
run;