The HPREG Procedure

(View the complete code for this example.)

This example shows how you can run PROC HPREG in single-machine and distributed modes. See the section Processing Modes in SAS/STAT 14.2 User's Guide: High-Performance Procedures for details about the execution modes of SAS High-Performance Statistics procedures. The focus of this example is to simply show how you can switch the modes of execution of PROC HPREG, rather than on any statistical features of the procedure. The following DATA step generates the data for this example. The response y depends on 20 of the 1,000 regressors.

 data ex2Data;
    array x{1000};

    do i=1 to 10000;
       y=1;
       sign=1;

       do j=1 to 1000;
          x{j} = ranuni(1);
          if j<=20  then do;
            y = y + sign*j*x{j};
            sign=-sign;
          end;
       end;
       y = y + 5*rannor(1);
       output;
   end;
 run;

The following statements use PROC HPREG to select a model by using BACKWARD selection:

 proc hpreg data=ex2Data;
     model y = x: ;
     selection method = backward;
     performance details;
 run;

Output 61.2.1 shows the "Performance Information" table. This shows that the HPREG procedure executes in single-machine mode using four threads because the client machine has four CPUs. You can force a certain number of threads on any machine involved in the computations with the NTHREADS option in the PERFORMANCE statement.

Output 61.2.2 shows the parameter estimates for the selected model. You can see that the default BACKWARD selection with selection and stopping based on the SBC criterion retains all 20 of the true effects but also keeps two extraneous effects.

Output 61.2.3 shows timing information for the PROC HPREG run. This table is produced when you specify the DETAILS option in the PERFORMANCE statement. You can see that, in this case, the majority of time is spent forming the crossproducts matrix for the model that contains all the regressors.

You can switch to running PROC HPREG in distributed mode by specifying valid values for the NODES=, INSTALL=, and HOST= options in the PERFORMANCE statement. An alternative to specifying the INSTALL= and HOST= options in the PERFORMANCE statement is to set appropriate values for the GRIDHOST and GRIDINSTALLLOC environment variables by using OPTIONS SET commands. See the section Processing Modes in SAS/STAT 14.2 User's Guide: High-Performance Procedures for details about setting these options or environment variables.

The following statements provide an example. To run these statements successfully, you need to set the macro variables GRIDHOST and GRIDINSTALLLOC to resolve to appropriate values, or you can replace the references to macro variables with appropriate values.

 proc hpreg data=ex2Data;
     model y = x: ;
     selection method = backward;
     performance details nodes = 10
                 host="&GRIDHOST" install="&GRIDINSTALLLOC";
 run;

The execution mode in the "Performance Information" table shown in Output 61.2.4 indicates that the calculations were performed in a distributed environment that uses 10 nodes, each of which uses eight threads.

Another indication of distributed execution is the following message issued by all high-performance statistical procedures in the SAS Log:

NOTE: The HPREG procedure is executing in the distributed
      computing environment with 10 worker nodes.

Output 61.2.5 shows timing information for this distributed run of the HPREG procedure. In contrast to the single-machine mode (where forming the crossproducts matrix dominated the time spent), the majority of time in distributed mode is spent distributing the data and performing the model selection.