The FREQ Procedure

(View the complete code for this example.)

When a binary response is measured several times or under different conditions, Cochran’s Q tests that the marginal probability of a positive response is unchanged across the times or conditions. When there are more than two response categories, you can use the CATMOD procedure to fit a repeated-measures model.

The data set Drugs contains data for a study of three drugs to treat a chronic disease (Agresti 2002). Forty-six subjects receive drugs A, B, and C. The response to each drug is either favorable ('F') or unfavorable ('U').

proc format;
   value $ResponseFmt 'F'='Favorable'
                      'U'='Unfavorable';
run;

data drugs;
   input Drug_A $ Drug_B $ Drug_C $ Count @@;
   datalines;
F F F  6   U F F  2
F F U 16   U F U  4
F U F  2   U U F  6
F U U  4   U U U  6
;

The following statements create one-way frequency tables of the responses to each drug. The AGREE option produces Cochran’s Q and other measures of agreement for the three-way table. These statements produce Output 41.10.1 through Output 41.10.5.

proc freq data=Drugs;
   tables Drug_A Drug_B Drug_C / nocum;
   tables Drug_A*Drug_B*Drug_C / agree noprint;
   format Drug_A Drug_B Drug_C $ResponseFmt.;
   weight Count;
   title 'Study of Three Drug Treatments for a Chronic Disease';
run;

The one-way frequency tables in Output 41.10.1 provide the marginal response for each drug. For drugs A and B, 61% of the subjects reported a favorable response; for drug C, 35% of the subjects reported a favorable response. Output 41.10.2 and Output 41.10.3 display measures of agreement for the 'Favorable' and 'Unfavorable' levels of drug A, respectively. McNemar’s test shows a strong discordance between drugs B and C when the response to drug A is favorable.

Output 41.10.4 displays the overall kappa coefficient. The small negative value of kappa indicates no agreement between drug B response and drug C response.

Cochran’s Q is statistically significant (p=0.0145 in Output 41.10.5), which leads to rejection of the hypothesis that the probability of favorable response is the same for the three drugs.