The CAUSALTRT Procedure

(View the complete code for this example.)

This example demonstrates how the CAUSALTRT procedure can use regression adjustment to estimate both the ATE (average treatment effect) and the ATT (average treatment effect for the treated). The question of interest in this example is the effect that attending a Catholic high school has on a student’s performance in mathematics. The data for this example are a subset of data from the National Educational Longitudinal Study of 1988 in Murnane and Willett (2011). Demographic information was collected from the students and their families along with standardized test scores in 1988 and subsequent follow-up years. The outcome for this example is the student’s score on the mathematics portion of the standardized tests in 1992.

The input data set School is shown in the following DATA step:

data School;
   input
   Income $ FatherEd $ MotherEd $ Math BaseMath  Catholic $;
   datalines;
   Middle HighSchool HighSchool 49.77 50.27 Yes
   Middle Unknown Unknown 59.84 51.52 Yes
   Middle NoHighSchool Postsecondary 50.38 47.56 Yes
   Middle Unknown Unknown 45.03 46.60 Yes
   High HighSchool HighSchool 54.26 60.22 Yes
   Low NoHighSchool HighSchool 55.37 58.63 Yes

   ... more lines ...   

   High SomeSecondary HighSchool 43.28 43.27 Yes
   Middle HighSchool HighSchool 41.69 48.29 Yes
   High College College 56.60 60.15 Yes
   High College SomeSecondary 56.29 59.53 Yes
   High College Postsecondary 58.16 57.06 Yes
   High College SomeSecondary 63.57 63.51 Yes
;

The data set School consists of records for 5,671 high school students whose 1988 total family income was at most $75,000. The variables in the data are as follows:

The following statements invoke the PROC CAUSALTRT procedure to estimate the ATE of attending a Catholic high school on math scores:

proc causaltrt data=school method=regadj poutcomemod;
   class Income FatherEd MotherEd;
   psmodel Catholic(ref='No');
   model Math = BaseMath Income FatherEd MotherEd;
run;

The METHOD=REGADJ option requests that regression adjustment be used to estimate the ATE. For this estimation method, models are fit for the outcome variable separately for each treatment condition. The treatment variable, Catholic, is listed in PSMODEL statement. The ref='No' option identifies Catholic='No' as the reference or control level. The outcome variable Math is specified in the MODEL statement along with the effects used to fit the outcome model.

The POUTCOMEMOD option in the PROC CAUSALTRT statement requests the display of the parameter estimates for the outcome model fit within each treatment condition. Two tables are produced: one for the control condition (Output 33.3.1) and one for the treatment condition (Output 33.3.2).

The potential outcome means and ATE are estimated by averaging predicted values for each student from each of the outcome models. The ATE estimate of 1.6920 in Output 33.3.3 indicates that attending a Catholic high school has a positive effect on math scores. This estimate for the treatment effect is much smaller than the estimate of 3.8949 that you would obtain by comparing the unadjusted average math scores for each treatment condition.

Conceptually, the ATE in this example is the average effect on the math scores for everyone in the population who would have attended a Catholic high school versus a non-Catholic high school. Causal effect analysis such as the current example enables you to estimate the ATE with causal interpretation, which is of general scientific interest.

However, for policy-making purposes, sometimes it is more interesting to examine the effectiveness of a program or treatment for those who did participate. The average treatment effect for the treated (ATT) is such a concept; it measures the treatment effect conditional on those who receive the treatment condition. PROC CAUSALTRT provides you two methods to estimate ATT: the inverse probability weighting method with ratio adjustment (METHOD=IPWR) or regression adjustment (METHOD=REGADJ).

The remainder of this section demonstrates the estimation of ATT for the Catholic high school data example. To estimate the average treatment effect for the treated, you specify the ATT option in the PROC CAUSALTRT statement. The following SAS statements estimate the ATT using the regression adjustment estimation method and the same outcome model as specified in the previous analysis for ATE:

proc causaltrt data=school method=regadj att;
   class Income FatherEd MotherEd;
   psmodel Catholic(ref='No');
   model Math = BaseMath Income FatherEd MotherEd;
run;

The "Analysis of Causal Effect" table now displays estimates for the ATT and the potential outcome means conditional on receiving the treatment condition. The estimate for the ATT is 1.5727, which is slightly smaller than the ATE estimate.

From a policy-making point of view, the average effect that attending a Catholic high school would have on students who are in non-Catholic high school would also be of interest. Such a mirror concept of ATT is also known as ATU, average treatment effect for the untreated. Although the CAUSALTRT procedure does not provide a direct option for estimating ATU, you can still achieve that purpose by using the ATT option with the reverse treatment designation. In the following PROC CAUSALTRT statements, the ref='Yes' option in the PSMODEL statement redefines the treatment condition to be attending a non-Catholic high school.

proc causaltrt data=school method=regadj att;
   class Income FatherEd MotherEd;
   psmodel Catholic(ref='Yes');
   model Math = BaseMath Income FatherEd MotherEd;
run;

The ATT estimate of –1.7059 in Output 33.3.5 is the average causal effect that attending non-Catholic high schools has on the math scores of students in non-Catholic high schools. Reversing the sign of this estimate provides an estimate for the ATU: the average treatment effect that attending a Catholic school would have for those students in non-Catholic high schools. Hence, the ATU in the current example is 1.7059.

In some research studies, researchers would like to compare ATT and ATU to investigate the so-called effect heterogeneity issue. In the current example, the ATU is only slightly larger (by about 0.13 points) than the ATT. Considering the fact that all potential outcome means are about 50, it thus appears to be safe to say that effect heterogeneity, as indicated by the 0.13 point difference, is not an issue in the current example.