PANEL Procedure

(View the complete code for this example.)

The Christenson Associates airline data are a frequently cited data set (Greene 2000). The data measure the costs, prices of inputs, and utilization rates for six airlines from 1970 to 1984. This example analyzes the cost (variable C), quantity (variable Q), and price (variable PF) and the untransformed load factor (variable LF). Because (1) all the variables vary over time, (2) the focus is on how these variables influence cost within each company, and (3) there is no strong reason to believe that the error terms are correlated among companies, a fixed-effects model would be the natural candidate. You propose the following model,

where the are airline effects. The actual model in the original, untransformed variables is highly nonlinear:

The following statements create the data set and perform the necessary log transformations:

data Airline;
   input Obs AirlineID T C Q PF LF;
   Year = T + 1969;
   lC   = log(C);
   lQ   = log(Q);
   lPF  = log(PF);
   label lC  = "Log Transformation of Costs";
   label lQ  = "Log Transformation of Quantity";
   label lPF = "Log Transformation of Price of Fuel";
   label LF  = "Load Factor (utilization index)";
datalines;
 1    1     1    1140640    0.95276     106650    0.53449
 2    1     2    1215690    0.98676     110307    0.53233
 3    1     3    1309570    1.09198     110574    0.54774
 4    1     4    1511530    1.17578     121974    0.54085
 5    1     5    1676730    1.16017     196606    0.59117

   ... more lines ...   

At the beginning of the analysis, it is natural to start with the most basic model, the pooled OLS model. The following statements run pooled OLS and check for fixed effects:

proc sort data = Airline;
   by AirlineID Year;
run;

proc panel data = Airline;
   id AirlineID Year;
   model lC = lQ lPF LF / pooled pooltest;
run;

Output 25.1.1 provides a description of the model and data. There are six cross sections and 15 time points.

The R-square statistic and degrees of freedom are shown in Output 25.1.2. The R-square statistic is fairly high, indicating a good fit.

You could still run the poolability test to check whether the model has any fixed effects. The POOLTEST option provides the poolability test; the results are shown in Output 25.1.3.

The Restricted Model column lists two models, FIXONE and POOLED. For the FIXONE model, the null hypothesis is a one-way fixed-effects model and the alternative hypothesis is a two-way fixed-effects model. The POOLED model tests the null hypothesis of a pooled OLS model against the alternative hypothesis of a one-way fixed-effects model. There are two types of poolability tests: an F test, as in the F column, and a likelihood ratio test, as in the LR column. Both the F test and the likelihood ratio test reject the one-way fixed-effects model and the pooled OLS model, as shown in Output 25.1.3, suggesting that a two-way fixed-effects model would be best. Before fitting a two-way fixed-effects model, you might want to fit a one-way fixed-effects model by using the following statements:

proc panel data = Airline;
   id AirlineID Year;
   model lC = lQ lPF LF / fixone printfixed;
run;

The R-square statistic and degrees of freedom are shown in Output 25.1.4. The R-square statistic is nearly 1 and higher than in the pooled OLS model, indicating a more reasonable fit. The error degrees of freedom is derived from 90 observations minus 5 cross sections minus 4 regressors.

The results of the F test for fixed effects are shown in Output 25.1.5. These test results also easily reject the null hypothesis of the pooled OLS model. There are significant effects due to airlines, and it would be unreasonable to perform a pooled OLS regression that ignores these effects.

The PRINTFIXED option in the MODEL statement provides estimates of the airline effects (which are not displayed by default). The intercept is parameterized as the fixed effect for Airline 6. The other fixed effects are differences from that base category. Quantity and fuel price have positive effects on cost, but load factors negatively affect costs. Because cost, quantity, and fuel price are log-transformed, the coefficients for quantity and price are interpreted as elasticities of cost. The coefficient for (log) fuel price is 0.417, meaning that you would associate a 10% increase in fuel price with a 4.17% increase in costs.

As suggested by the poolability test results in Output 25.1.3, you suspect that there might be other factors at play, so you augment your model to include time effects. The following statements fit a two-way model, which is a model that has both airline effects and time effects:

proc panel data = Airline;
   id AirlineID Year;
   model lC = lQ lPF LF / fixtwo printfixed;
run;

The fit statistics, F test, and parameter estimates for the two-way model are provided in Output 25.1.7.

There is an overall time trend of increasing costs. The time period of the data spans the OPEC oil embargoes and the dissolution of the Civil Aeronautics Board (CAB). These are two possible explanations for the rising costs.

A surprising result is that the fuel cost is not significant in the two-way model. If the time effects are proxies for the effect of the oil embargoes, then the effect of fuel price might be subsumed by the time effects. If the time dummy variables are proxies for the dissolution of the CAB, then the effect of load factors is not precisely estimated.

ODS Graphics Plots

PROC PANEL can generate ODS plots to graphically analyze the results and perform diagnostics. The following statements show how to use the PLOTS=ALL option to generate all available plots. For a complete list of options, see the section Creating ODS Graphics.

ods graphics on;
proc panel data = Airline;
   id AirlineID Year;
   model lC = lQ lPF LF / fixtwo plots = all;
run;

Specifying PLOTS=ALL produces two panels of plots, shown in Output 25.1.8 and Output 25.1.9.

Output 25.1.8: Airline Cost Data, Diagnostic Panel 1

Output 25.1.9: Airline Cost Data, Diagnostic Panel 2

The following statements demonstrate how to use the UNPACK option to unpack the panels into single plots, and how to use the ONLY option to select only a surface plot of residuals:

proc panel data = Airline;
   id AirlineID Year;
   model lC = lQ lPF LF / fixtwo plots(unpack only) = residsurface;
run;

The unpacked residual-surface plot is shown in Output 25.1.10.

Output 25.1.10: Airline Cost Data, Surface Plot of the Residuals