FREQTAB Procedure

(View the complete code for this example.)

This example shows you how to use the FREQTAB procedure to construct crosstabulation tables and produce chi-square statistics and measures of association.

The data table mylib.School_Survey consists of hypothetical data that are based on a customer satisfaction survey for a school information system. This data table includes the following variables for the survey respondents: ID (respondent identification), Response, SchoolType, and State. Figure 1 displays the first 20 observations of the data table.

Note: Input data must be in a CAS table that is accessible in your CAS session. You must refer to this table by using a two-level name. The first level must be a CAS engine libref, and the second level must be the table name. For more information, see the sections Using CAS Sessions and CAS Engine Librefs and Loading a SAS Data Set onto a CAS Server in Chapter 2, Shared Concepts.

The following PROC FREQTAB statements request a two-way crosstabulation of SchoolType and Response. These statements assume that your libref is named mylib, but you can substitute any appropriately defined libref.

proc freqtab data=mylib.School_Survey;
   tables SchoolType * Response /
      crosslist chisq measures(cl);
run;

The PROC FREQTAB statement invokes the procedure and identifies the data table to be analyzed. The TABLES statement requests a two-way crosstabulation of SchoolType and Response. The table request syntax in PROC FREQTAB is identical to the table request syntax in the FREQ procedure. You can specify one-way, two-way, and multiway table requests. You can specify more than one table request in the same TABLES statement, and you can specify multiple TABLES statements in the same invocation of the procedure.

The CROSSLIST option displays the crosstabulation table in column format; by default, PROC FREQTAB displays crosstabulation tables in table cell format. The CHISQ option requests chi-square tests, and the MEASURES option requests measures of association for this two-way crosstabulation table. The MEASURES(CL) option requests confidence limits for the measures of association.

Figure 2 shows the crosstabulation table of SchoolType by Response. You can customize the contents of this table by specifying options in the TABLES statement. For example, the NOCOL option suppresses the column percentages, the EXPECTED option displays the expected cell frequencies (under independence), and the STDRES option displays the standardized residuals.

Figure 3 shows the chi-square statistics, and Figure 4 shows the measures of association for the table of SchoolType and Response.

PROC FREQTAB can produce plots as part of its output by using ODS Graphics. The following statements show how to produce a frequency plot and a mosaic plot for a two-way crosstabulation table. The ODS GRAPHICS ON statement enables ODS Graphics, which is required in order to produce plots.

The PLOTS=FREQPLOT option in the TABLES statement requests a frequency plot of the two-way table of Response by SchoolType. The TWOWAY=CLUSTER plot-option requests a cluster grouped bar chart. The ORIENT=H plot-option specifies horizontal orientation, which places the variable levels on the Y-axis and the percentages on the X-axis. The SCALE=GROUPPERCENT plot-option requests a plot of group (column) percentages (instead of frequencies).

The PLOTS=MOSAICPLOT option requests a mosaic plot of Response by SchoolType. The COLORSTAT=STDRES plot-option colors the mosaic plot tiles according to the standardized residuals of the corresponding table cells.

ods graphics on;
proc freqtab data=mylib.School_Survey;
   tables Response * SchoolType /
      plots=(freqplot(twoway=cluster orient=h scale=grouppercent)
             mosaicplot(colorstat=stdres));
run;
ods graphics off;

Figure 5 displays the two-way frequency plot of SchoolType and Response. Figure 6 displays the mosaic plot of this crosstabulation.

The following PROC FREQTAB statements produce a multiway table of State by SchoolType by Response. The TABLES statement requests the multiway table in which SchoolType is the row variable, Response is the column variable, and State is the stratum variable. This request produces a separate two-way table of SchoolType by Response for each level (stratum) of the variable State. The CMH option in the TABLES statement requests stratified analysis, which adjusts for the effect of State.

proc freqtab data=mylib.School_Survey;
   tables State * SchoolType * Response / cmh;
run;

Figure 7 displays the two-way table of SchoolType and Response for State = 'GA'. PROC FREQTAB also produces two-way tables for the other states, but these results are not displayed here. Figure 8 displays the CMH summary statistics.