CARIMA Procedure

The airline passenger data have been used in time series analysis literature as an example of a nonstationary seasonal time series.

The following statements plot the air data:

proc sgplot data=sashelp.air;
  series x = date y = air;
run;

Output 5.1.1 indicates that the series is nonstationary and seasonal.

The following DATA step loads the air data into a CAS session. The DATA step assumes that the SAS library is named mylib, but you can substitute any appropriately named SAS library.

data mylib.myair;
   set sashelp.air;
run;

You can use the following statements to fit an ARIMA(0,1,1)(0,1,1) model without a mean term to the logarithms of the airline passengers series. The model estimates and forecasts are stored in the data tables mylib.cariest and mylib.carifor.

proc carima data=mylib.myair outest=mylib.cariest outfor=mylib.carifor;
  id date interval=month;
  identify air;
  estimate q=(1)(12) noint  method = ML transform = log diff = (1,12);
  forecast lead = 4;
run;

Output 5.1.2 shows the summary of the time series processing.

Output 5.1.3 shows the name of the modeled variable.

Output 5.1.4 shows the parameter estimates from the fitted model.

Output 5.1.5 shows the multistep-ahead variable forecasts.

The following statements plot the forecasts that are produced by the ARIMA(0,1,1)(0,1,1) model. The plot is shown in Output 5.1.6.

proc sgplot data=mylib.carifor;
  series x=date y=actual / markers lineattrs=(color=red)
                           markerattrs=(symbol=circlefilled color=red);
  series x=date y=predict / markers lineattrs=(color=blue)
                            markerattrs=(symbol=asterisk color=blue);
  refline '01JAN1959'd / axis=x;
run;