Optimization Action Set

This section contains PROC CAS code.

Note: Input data must be accessible in your CAS session, either as a CAS table or as a transient-scope table. A CAS table has a two-level name: the first level is your CAS engine libref, and the second level is the table name. You refer to this table in the CAS procedure by specifying only the second level. For more information about two-level names, see Chapter 3, Shared Concepts (SAS Optimization: Mathematical Optimization Procedures). A transient-scope table is called directly from the action and exists in memory for the duration of the action. For more information about accessing data, see SAS Viya: System Programming Guide. For more information about PROC CAS and programming in CASL, see SAS Cloud Analytic Services: CASL Programmer’s Guide and SAS Cloud Analytic Services: CASL Reference.

The following example illustrates how you can use the solveQp action to solve quadratic programs. Suppose you want to solve the following problem:

The preceding problem can be expressed in the following manner in an input data table that uses a quadratic programming system (QPS) format. The DATA step assumes that your CAS engine libref is named mycas, but you can substitute any appropriately defined CAS engine libref.

data mycas.example;
   input _id_ field1 $ field2 $ field3 $ field4 field5 $ field6 @;
   datalines;
1  NAME     .      EXAMPLE    .             .         .
2  ROWS     .      .          .             .         .
3  N        OBJ    .          .             .         .
4  L        R1     .          .             .         .
5  G        R2     .          .             .         .
6  COLUMNS  .      .          .             .         .
7  .        X1     R1         1.0           R2        1.0
8  .        X1     OBJ        2.0           .         .
9  .        X2     R1        -1.0           R2        2.0
10 .        X2     OBJ        3.0           .         .
11 RHS      .      .          .             .         .
12 .        RHS    R1         1.0           .         .
13 .        RHS    R2         100           .         .
14 RANGES   .      .          .             .         .
15 BOUNDS   .      .          .             .         .
16 QUADOBJ  .      .          .             .         .
17 .        X1     X1         2.0           .         .
18 .        X1     X2         2.5           .         .
19 .        X2     X2         20            .         .
20 ENDATA   .      .          .             .         .
;

You can use the following call to PROC CAS to solve the QP problem:

proc cas;
   loadactionset "optimization";
   action optimization.solveQp result=r status=s /
      data={name="example"}
      primalOut={name="expout" replace=true}
      dualOut={name="exdout" replace=true}
      numThreads=4
      objSense="min"
      logFreq=1;
   run;
   print r.SolutionSummary; run;
   action table.fetch / table = "expout"; run;
quit;

The primal solution is displayed in Output 2.14.1.

The progress of the solution is printed to the log, as shown in Output 2.14.2.

The PRINT statement that follows immediately after the PROC CAS step prints the value of the SolutionSummary results table to the log, as shown in Output 2.14.3.