EXTRACTOBJECTS Procedure

(View the complete code for this example.)

The example in this section shows how to use the EXTRACTOBJECTS procedure in conjunction with PROC LOADIMAGES and PROC FEDSQL to highlight detected objects in an image.

The following PROC LOADIMAGES statement loads an image into the mylib.images table. You can use the PRINT procedure to display the contents of this table. Also, you can use the DISPLAYIMAGES procedure to display the original input image.

proc loadimages libref=mylib path='path/to/birds.png';
   output out=mylib.images addvars=(width height);
run;
proc print data=mylib.images;
run;
proc displayimages data=mylib.images;
run;

Figure 1 shows that the mylib.images table contains an image with a height of 448 pixels and a width of 448 pixels.

Figure 2 shows the ODS output of PROC DISPLAYIMAGES.

You can use PROC FEDSQL as follows to add the object annotations in RECT format (see the section Supported Image Annotation Formats) to the mylib.images table. Because there are two birds in the input image, you can add annotations for two objects.

proc fedsql sessref=mysess;
   create table images_annotations as
   select
      *,
      2 as "_nObjects_",

      'bird0' as "_Object0_",
      4 as "_Object0_x", 23 as "_Object0_y",
      201 as "_Object0_width", 144 as "_Object0_height",

      'bird1' as "_Object1_",
      191 as "_Object1_x", 116 as "_Object1_y",
      197 as "_Object1_width", 147 as "_Object1_height"
   from
      images;
quit;

Note: These statements create the mylib.images_annotations table by using the image binaries and metadata from the mylib.images table and adding annotation variables in RECT format. By default, PROC EXTRACTOBJECTS assumes that coordinates are in RECT format. Therefore, you must specify the following variables for each detected object in the mylib.images_annotations table, where N denotes the Nth detected object:

The following PROC PRINT statement displays the mylib.images_annotations table, which is generated by the previous statements:

proc print data=mylib.images_annotations;
run;

Figure 3 shows the mylib.images_annotations table.

Finally, you use PROC EXTRACTOBJECTS as follows to highlight the two birds in the original image and save the output in the mylib.objects table:

proc extractobjects data=mylib.images_annotations
   coordinateformat=rect maxobjects=2;
   output out=mylib.objects;
run;

You can use PROC PRINT as follows to display the mylib.objects table. Again, you can use PROC DISPLAYIMAGES to display the highlighted image.

proc print data=mylib.objects;
run;
proc displayimages data=mylib.objects;
run;

Figure 4 shows that the mylib.objects table resembles a typical image table.

Figure 5 shows the ODS output of PROC DISPLAYIMAGES.