CORRELATION Procedure

(View the complete code for this example.)

The following statements create the data table Fish1. The cubic root of the weight (Weight3) is computed as a one-dimensional measure of the size of a fish.

*------------------- Fish Measurement Data -----------------------*
| The data table contains 35 fish from the species Bream caught   |
| in Finland's Lake Laengelmavesi with the following measurements:|
| Weight   (in grams)                                             |
| Length3  (length from the nose to the end of the tail, in cm)   |
| HtPct    (max height, as percentage of Length3)                 |
| WidthPct (max width,  as percentage of Length3)                 |
*-----------------------------------------------------------------*;
data mylib.Fish1 (drop=HtPct WidthPct);
   title 'Fish Measurement Data';
   input Weight Length3 HtPct WidthPct @@;
   Weight3= Weight**(1/3);
   Height=HtPct*Length3/100;
   Width=WidthPct*Length3/100;
   datalines;
242.0 30.0 38.4 13.4     290.0 31.2 40.0 13.8
340.0 31.1 39.8 15.1     363.0 33.5 38.0 13.3
430.0 34.0 36.6 15.1     450.0 34.7 39.2 14.2
500.0 34.5 41.1 15.3     390.0 35.0 36.2 13.4
450.0 35.1 39.9 13.8     500.0 36.2 39.3 13.7
475.0 36.2 39.4 14.1     500.0 36.2 39.7 13.3
500.0 36.4 37.8 12.0        .  37.3 37.3 13.6
600.0 37.2 40.2 13.9     600.0 37.2 41.5 15.0
700.0 38.3 38.8 13.8     700.0 38.5 38.8 13.5
610.0 38.6 40.5 13.3     650.0 38.7 37.4 14.8
575.0 39.5 38.3 14.1     685.0 39.2 40.8 13.7
620.0 39.7 39.1 13.3     680.0 40.6 38.1 15.1
700.0 40.5 40.1 13.8     725.0 40.9 40.0 14.8
720.0 40.6 40.3 15.0     714.0 41.5 39.8 14.1
850.0 41.6 40.6 14.9    1000.0 42.6 44.5 15.5
920.0 44.1 40.9 14.3     955.0 44.0 41.1 14.3
925.0 45.3 41.4 14.9     975.0 45.9 40.6 14.7
950.0 46.5 37.9 13.7
;

The following statements request a correlation analysis and compute Cronbach’s coefficient alpha for the variables Weight3, Length3, Height, and Width:

title 'Fish Measurement Data';
proc correlation data=mylib.fish1 nomiss alpha;
   var Weight3 Length3 Height Width;
run;

The ALPHA option computes Cronbach’s coefficient alpha for the analysis variables.

The "Simple Statistics" table in Output 9.2.1 displays univariate descriptive statistics for each analysis variable.

The "Pearson Correlation Coefficients" table in Output 9.2.2 displays Pearson correlation statistics for pairs of analysis variables.

Because the data table contains only one species of fish, all the variables are highly correlated. Using the ALPHA option, the CORRELATION procedure computes Cronbach’s coefficient alpha in Output 9.2.3. The Cronbach’s coefficient alpha is a lower bound for the reliability coefficient for the raw variables and the standardized variables. Positive correlation is needed for the alpha coefficient because variables measure a common entity.

Because the variances of some variables vary widely, you should use the standardized score to estimate reliability. The overall standardized Cronbach’s coefficient alpha of 0.985145 provides an acceptable lower bound for the reliability coefficient. This is much greater than the suggested value of 0.70 given by Nunnally and Bernstein (1994).

The standardized alpha coefficient provides information about how each variable reflects the reliability of the scale with standardized variables. If the standardized alpha decreases after removing a variable from the construct, then this variable is strongly correlated with other variables in the scale. On the other hand, if the standardized alpha increases after removing a variable from the construct, then removing this variable from the scale makes the construct more reliable. The "Cronbach Coefficient Alpha with Deleted Variables" table in Output 9.2.4 does not show a significant increase or decrease in the standardized alpha coefficients. For more information about Cronbach’s alpha, see the section Cronbach’s Coefficient Alpha.