DEEPPRICE Procedure

This example illustrates how the DEEPPRICE procedure estimates the parameters of interest and performs policy evaluation and policy comparison when the treatment variable is endogenous. In this case, the instrumental variable should be used. This example also demonstrates how you can save the model information and use it later to score other new data.

A simulated data set is generated, based on the following assumptions:

The treatment model is given as

where describes the seasonality.

The outcome model is given as

Note that and are correlated, which indicates that the scaled flight price is endogenous.

The following statements simulate samples that are based on the treatment and outcome models that were just presented:

%let n=12500;
%let rho = 2;
%let seed=12346;
%deepPriceGenerateData(&n.,&rho.,&seed.);

The following DATA steps load the first observations of the data set deepPriceDGP into the data table simPrice_train and the next observations into the data table simPrice_test in your session that is associated with the mylib libref. The DATA steps assume that your libref is named mylib, but you can substitute any appropriately defined libref.

data mylib.simPrice_train;
   set deepPriceDGP(obs=10000 keep=i s t z p y R pstar);
run;

data mylib.simPrice_test;
   set deepPriceDGP(firstobs=10001 keep=i s t z p y R pstar);
run;

The unknown functions , , , and are estimated through two DNNs by using the simPrice_train data table. The parameters of interest are then estimated, and the policy evaluation and policy comparison are performed. The instrumental variable is introduced into the model by using the INSTRUMENT statement. The following statements use PROC DEEPPRICE to perform these tasks and store the model information and parameter learning results:

proc deepprice data=mylib.simPrice_train;
   id i;
   instrument z;
   tmodel p=s t / dnn=(nodes=(32 32 32 32)
         train=(optimizer=(miniBatchSize=2000 regL1=0.001 maxEpochs=2000
         algorithm=adam) nthreads=5 seed=12346 recordseed=12346));
   model y=s t / dnn=(nodes=(32 32 32 32)
         train=(optimizer=(miniBatchSize=2000 regL1=0.001 maxEpochs=8000
         algorithm=adam) nthreads=5 seed=12346 recordseed=12346));
   infer policy=(pstar) policyComparison=(base=(p) compare=(pstar))
      out=mylib.oest outdetails=mylib.odetails;
   score outeta0=mylib.outeta0data outeta1=mylib.outeta1data
      outa=mylib.outadata outb=mylib.outbdata;
run;

The OUTETA0= option writes the estimation information to the data table outeta0data, the OUTETA1= option writes the estimation information to the data table outeta1data, the OUTA= option writes the estimation information to the data table outadata, and the OUTB= option writes the estimation information to the data table outbdata. The number of observations is shown in Figure 7.

The estimates of parameters of interest are shown in Figure 8.

The policy evaluation estimates the expected demand of a policy. The policy evaluation results are shown in Figure 9.

The policy comparison estimates the difference in expected demand between two policies. The policy comparison results are shown in Figure 10.

According to the comparison of two policies, the policy p in the observed data generates more demand on average than the policy pstar; however, this does not mean that p generates more revenue than pstar! In fact, in the real world, although pstar is theoretically the best policy to maximize revenue, it cannot be available because it needs the unknown functions and . Because of the availability of the true data generating process (DGP), the revenue that the optimized policies generate that is suggested by the plug-in estimator and influence-function estimator can be compared to that of the best-in-theory infeasible policy pstar. The following statements compare the actual function values in the true DGP to the estimates of , , , and , which are _eta0_, _eta1_, _alpha_, and _beta_, respectively, in the oDetails data table in your session; compare the revenues that are generated through different policies; and use PROC MEANS to get the bias and variance of each estimator:

proc sort data=mylib.odetails out=odetails_tmp;
   by i;
run;

data odetails;
   merge odetails_tmp(in=a) deepPriceDGP(in=b where=(i<=10000));
   by i;
   diff_eta0 = _eta0_ - eta0;
   diff_eta1 = _eta1_ - eta1;
   diff_alpha = _alpha_-alpha;
   diff_beta  = _beta_ -beta;
   * revenue difference between observed policy and best policy;
   diff_R = R0 - Rstar;
   * ifpstar, the optimized policy suggested by influence-function
     estimator;
   if(_if_beta_<0) then ifpstar = -_if_alpha_/_if_beta_/2;
   else ifpstar = pub;
   if(ifpstar>pub) then ifpstar = pub;
   if(ifpstar<plb) then ifpstar = plb;
   ifystar = alpha + beta * ifpstar;
   if(ifystar<0) then ifystar=0;
   ifRstar = ifystar * ifpstar;
   * revenue difference between influence-function optimized policy and
     best policy;
   diff_ifR = ifRstar - Rstar;
   * pipstar, the optimized policy suggested by plug-in estimator;
   if(_beta_<0) then pipstar = -_alpha_/_beta_/2;
   else pipstar = pub;
   if(pipstar>pub) then pipstar = pub;
   if(pipstar<plb) then pipstar = plb;
   piystar = alpha + beta * pipstar;
   if(piystar<0) then piystar=0;
   piRstar = piystar * pipstar;
   * revenue difference between plug-in optimized policy and best policy;
   diff_piR = piRstar - Rstar;
run;

proc means data=odetails;
   var diff_eta0 diff_eta1 diff_alpha diff_beta diff_R diff_ifR diff_piR;
run;

The results are displayed in Figure 11, which shows that all four estimated functions are unbiased and also that the plug-in optimized policy is the best feasible policy.

You can apply the previously saved estimation information, estimation information, estimation information, and estimation information to a new data set by specifying the INETA0=, INETA1=, INA=, and INB= options, respectively, in the SCORE statement. The following statements use the outeta0data, outeta1data, outadata, and outbdata data tables as input data tables and then estimate the parameters of interest and perform the policy evaluation and comparison by using the simPrice_test data table:

proc deepprice data=mylib.simPrice_test;
   id i;
   instrument z;
   infer policy=(pstar) policyComparison=(base=(p) compare=(pstar))
      out=mylib.oest2 outdetails=mylib.odetails2;
   score ineta0=mylib.outeta0data ineta1=mylib.outeta1data
      ina=mylib.outadata inb=mylib.outbdata;
run;

When you specify the INETA0=, INETA1=, INA=, and INB= options in the SCORE statement, you do not need to specify the TMODEL or MODEL statement. The estimates of parameters of interest and the results of the policy evaluation and policy comparison are shown in Figure 12.

For more information about the estimates of parameters of interest, policy evaluation, and policy comparison, see the sections Average Intercept and Slope Parameters and Policy Evaluation and Comparison.