Network Action Set

This section contains PROC CAS code.

Note: Input data must be accessible in your CAS session, either as one or more CAS tables or as one or more transient-scope tables. A CAS table has a two-level name: the first level is your CAS engine libref, and the second level is the table name. You refer to this table in the CAS procedure by specifying only the second level. For more information about two-level names, see Chapter 2, Shared Concepts (SAS Viya: Machine Learning Procedures). A transient-scope table is called directly from the action and exists in memory for the duration of the action. For more information about accessing data, see SAS Viya: System Programming Guide. For more information about PROC CAS and programming in CASL, see SAS Cloud Analytic Services: CASL Programmer’s Guide and SAS Cloud Analytic Services: CASL Reference.

This section illustrates the use of the reach action on the directed graph G shown in Figure 18.

The directed graph G can be represented using the following links data set, LinkSetIn:

data LinkSetIn;
   input from $ to $ @@;
   datalines;
A B  A C  A D  B C  B E
B F  C E  D E  E D  E F
F G  G H  G I  H G  H I
;

Consider two sets of source nodes, and . These source node sets can be defined together as follows:

data NodeSubSetIn;
   input node $ reach;
   datalines;
A 2
C 1
H 2
;

The following DATA steps load the LinkSetIn and NodeSubSetIn data sets into CAS data tables named mylib.LinkSetIn and mylib.NodeSubSetIn. These statements assume that the CAS engine libref is named mylib, but you can substitute any appropriately defined CAS engine libref.

data mylib.LinkSetIn;
   set LinkSetIn;
run;
data mylib.NodeSubSetIn;
   set NodeSubSetIn;
run;

You can use the following statements to find the reach network that is restricted by a hop limit of 1 from both sets of source nodes:

proc cas;
   loadactionset "network";
   action reach result=r status=s /
      direction     = "directed"
      links         = {name = "LinkSetIn"}
      nodessubset   = {name = "NodeSubSetIn"}
      outReachNodes = {name = "ReachNodes", replace=true}
      outReachlinks = {name = "ReachLinks", replace=true}
      outCounts     = {name = "ReachCounts", replace=true}
      maxreach      = 1;
   run;
   print r.ProblemSummary; run;
   print r.SolutionSummary; run;
   action table.fetch / table = "ReachNodes" sortBy = {"reach", "node"}; run;
   action table.fetch / table = "ReachLinks" sortBy = {"reach", "from", "to"}; run;
   action table.fetch / table = "ReachCounts" sortBy = {"reach", "node"}; run;
quit;

The problem summary output from this action is shown in Output 28.15.1.

The solution summary output from this action is shown in Output 28.15.2.

The output data tables ReachNodes, ReachLinks, and ReachCounts now contain the nodes, links, and counts of the reach networks, respectively, that come from and . They are shown in Output 28.15.3 through Output 28.15.5.

s:loadtable{casLib="casuser", path="LinkSetIn.csv"}
s:loadtable{casLib="casuser", path="NodeSubSetIn.csv"}

s:network_reach{
   direction     = "directed",
   links         = {name = "LinkSetIn"},
   nodessubset   = {name = "NodeSubSetIn"},
   outReachNodes = {name = "ReachNodes", replace=true},
   outReachlinks = {name = "ReachLinks", replace=true},
   outCounts     = {name = "ReachCounts", replace=true},
   maxreach      = 1}

s.upload_file('LinkSetIn.csv')
s.upload_file('NodeSubSetIn.csv')

 s.network.reach(
     direction     = "directed",
     links         = {"name":"LinkSetIn"},
     nodessubset   = {"name":"NodeSubSetIn"},
     outReachNodes = {"name":"ReachNodes",  "replace":True},
     outReachLinks = {"name":"ReachLinks",  "replace":True},
     outCounts     = {"name":"ReachCounts", "replace":True},
     maxreach      = 1)