The ICA Procedure

This example demonstrates that applying dimension reduction in PROC ICA provides a better estimate of the independent components by using simulated data, compared to extracting the independent components without reducing the dimension of the data. The data that this example uses are from the Getting Started section, and an extra noise signal (x4) is added to the observed signal mixtures. The following DATA step generates the data:

data mycas.ex1data;
   keep t x:;
   array S[200,3];     /* S: source signals */
   array A[3,3];       /* A: mixing matrix */
   array x[4] x1-x4;   /* X: observed signals */

   N = 200;

   do i = 1 to 3;
      do j = 1 to 3;
         A[i,j] = 0.7*uniform(12345);
      end;
   end;

   do i = 1 to N;
      S[i,1] = cos(i/3);
      S[i,2] = 0.4*((mod(i,23)-11)/7)**5;
      S[i,3] = ((mod(i,29)-7)/11)-0.7;
   end;

   do i = 1 to N;
      t = i;
      do j = 1 to 3;
         x[j] = 0;
         do k = 1 to 3;
            x[j] = x[j] + S[i,k]*A[k,j];
         end;
      end;
      x[4] = 0.1*uniform(67890);
      output;
   end;
run;

These statements assume that your CAS engine libref is named mycas, but you can substitute any appropriately defined CAS engine libref.

The following statements extract the independent components by using dimension reduction and output the computed independent components to an output data table:

proc ica data=mycas.ex1data eigthresh=0.004 noscale seed=345;
   var x1-x4;
   output out=mycas.scores1 component=c copyvar=t;
run;

Output 8.1.1 displays the PROC ICA output. The "Model Information" table shows that the eigenvalue proportion threshold is set to 0.004. The "Dimensions" table indicates that there are four variables to be analyzed and four independent components to be computed. It also shows that three whitened variables are generated by using whitening and three independent components are actually extracted, thanks to the use of dimension reduction.

You can produce a plot of the computed independent components by using the output data table mycas.scores1 and the SGRENDER procedure, as shown in the following statements:

proc template;
   define statgraph ScoresPanel;
      beginGraph;
         layout lattice / rows=3
                          columns=1
                          rowgutter=10
                          columndatarange=unionall
                          order=packed;

         columnaxes;
            columnaxis / label="t";
         endcolumnaxes;

         layout overlay / yaxisopts=
            (linearopts=(viewmin=-3 viewmax=3 tickvaluelist=(-3 0 3)));
            seriesplot x=t y=c1;
         endlayout;

         layout overlay / yaxisopts=
            (linearopts=(viewmin=-2 viewmax=2 tickvaluelist=(-2 0 2)));
            seriesplot x=t y=c2;
         endlayout;

         layout overlay / yaxisopts=
            (linearopts=(viewmin=-2 viewmax=2 tickvaluelist=(-2 0 2)));
            seriesplot x=t y=c3;
         endlayout;

         endlayout;
      endGraph;
   end;
run;

proc sgrender data=mycas.scores1 template=ScoresPanel;
run;

Output 8.1.2 displays the computed independent components. The original source signals (s1, s2, and s3) in Figure 8.1 are accurately estimated by the computed independent components (c1, c2, and c3) up to multiplicative signed scalars.

Output 8.1.2: Independent Components Computed with Dimension Reduction

The following statements extract the independent components by using all dimensions of the input data (x1–x4) and output the computed independent components to an output data table:

proc ica data=mycas.ex1data noscale seed=345;
   var x1-x4;
   output out=mycas.scores2 component=c copyvar=t;
run;

Output 8.1.3 displays the computed independent components by using the output data table mycas.scores2 and PROC SGRENDER (code not shown). The original source signals (s1, s2, and s3) in Figure 8.1 are closely estimated by the three computed independent components (c2, c3, and c4) up to multiplicative signed scalars. However, you can clearly see that the estimates are affected by the addition of the noise signal (x4) compared to the independent components that are computed using dimension reduction in Output 8.1.2. Because there are fewer independent components than analysis variables in the input data, the computed component c1 is the projection pursuit direction.

Output 8.1.3: Independent Components Computed with Full Dimensions