Time Series Model Package

In some cases, it is useful to save the model specification and parameter estimates that are computed during an analysis for later use. For example, you can use the saved model specification and parameter estimates to produce model forecasts at a later stage (possibly with new measurements appended to the original data). This example shows how you can do the following:

The following statements fit the airline model to the airline series (see Example 32.1 for more information about the airline series and the airline model). The model specification and parameter estimates are stored in the tables mylib.airOSpec and mylib.airEst, respectively.

proc tsmodel data=mylib.air
   outobj=(airEst=mylib.airEst airOSpec=mylib.airOSpec) ;
   id date interval=month;
   var air;
   require tsm;
   submit;

      *** Analysis based on airline model ***;
      declare object airModel(tsm);
      declare object airSpec(arimaspec);
      declare object airEst(tsmpest);
      declare object airOSpec(tsmspec);

      array diff[2]/nosymbols;
      array ma[1]/nosymbols;

      *** Set up the airline model spec:   ***;
      ** Model: log(air) ~ (0,1,1)(0,1,1)12 noint ***;
      rc = airSpec.Open();
      *** Specify differencing orders ***;
      diff[1] = 1;
      diff[2] = 12;
      rc = airSpec.SetDiff(diff,2);
      *** Specify moving average orders: q = (1)(12)   ***;
      *** Use AddMAPoly twice  for the two factors   ***;
      ma[1] = 1;
      rc = airSpec.AddMAPoly(ma);
      ma[1] = 12;
      rc = airSpec.AddMAPoly(ma);
      *** Specify NOINT             ***;
      rc = airSpec.SetOption('noint',1);
      *** Specify the log transform     ***;
      rc = airSpec.SetTransform('log');
      *** Done setting up the ARIMA model ***;
      rc = airSpec.Close();

      *** Set up and run the TSM object ***;
      rc = airModel.Initialize(airSpec);
      rc = airModel.SetY(Air);
      rc = airModel.SetOption('lead',12);
      rc = airModel.Run();

      *** Output airline model spec and estimates ***;
      rc = airEst.Collect(airModel);
      rc = airOSpec.Collect(airModel);
  endsubmit;
quit;

Output 32.3.1 shows the parameter estimates that are saved in mylib.airEst.

The following statements show how to forecast the airline series by using the previously saved model specification (mylib.airOSpec) and parameter estimates (mylib.airEst).

proc tsmodel data=mylib.air
             outobj=(airFor=mylib.airFor)
             inobj=(airEst=mylib.airEst airSpec=mylib.airOSpec) ;
   id date interval=month;
   var air;
   require tsm;
   submit;

      *** Analysis based on the airline model ***;
      declare object airModel(tsm);
      declare object airSpec(tsminspec);
      declare object airEst(tsminest);
      declare object airFor(tsmfor);

      *** Set up and run the TSM object ***;
      rc = airModel.Initialize();
      rc = airModel.SetY(Air);
      rc = airModel.SetOption('lead',12);
      rc = airModel.Replay(airSpec,airEst);
      rc = airModel.Run();

      *** Output the airline model forecasts ***;
      rc = airFor.Collect(airModel);
  endsubmit;
quit;

Output 32.3.2 shows the forecasts that are produced according to the fitted model.