Network Action Set

This section contains PROC CAS code.

Note: Input data must be accessible in your CAS session, either as one or more CAS tables or as one or more transient-scope tables. A CAS table has a two-level name: the first level is your CAS engine libref, and the second level is the table name. You refer to this table in the CAS procedure by specifying only the second level. For more information about two-level names, see Chapter 2, Shared Concepts (SAS Visual Data Mining and Machine Learning: Procedures). A transient-scope table is called directly from the action and exists in memory for the duration of the action. For more information about accessing data, see SAS Viya: System Programming Guide. For more information about PROC CAS and programming in CASL, see SAS Cloud Analytic Services: CASL Programmer’s Guide and SAS Cloud Analytic Services: CASL Reference.

This example illustrates the use of the pattern matching algorithm on the directed graph G shown in Figure 11.

Figure 11: Directed Graph G

The directed graph G can be represented using the links data set, Links, and nodes data set, Nodes, that are created by the following DATA steps:

data Links;
   input from $ to $ @@;
   datalines;
A B A I A H
B D B E B C
C F C G C A
F G F A G B
E C I H D G
F C C D D E
;
data Nodes;
   input node $ @@;
   label=node;
   datalines;
A B C D E F G H I
;

The following DATA steps load the Links and Nodes data sets into CAS data tables named mycas.Links and mycas.Nodes. These statements assume that the CAS engine libref is named mycas, but you can substitute any appropriately defined CAS engine libref.

data mycas.Links;
   set Links;
run;
data mycas.Nodes;
   set Nodes;
run;

Each node has a node attribute label that is defined as the name of the node.

In this example, you want to find all subgraphs that are directed cycles of length 3 that pass through node C. The query graph Q that defines the pattern to search for is shown in Figure 12.

Figure 12: Query Graph Q

The query graph Q can be represented using the links data set, LinksQuery, and nodes data set, NodesQuery, that are created by the following DATA steps:

data LinksQuery;
   input from to;
   datalines;
1 2
2 3
3 1
;
data NodesQuery;
   input node label $;
   datalines;
2 C
;

The following DATA steps load the LinksQuery and NodesQuery data sets into CAS data tables named mycas.LinksQuery and mycas.NodesQuery. These statements assume that the CAS engine libref is named mycas, but you can substitute any appropriately defined CAS engine libref.

data mycas.LinksQuery;
   set LinksQuery;
run;
data mycas.NodesQuery;
   set NodesQuery;
run;

You can use the following statements to find all subgraphs that have the specified pattern:

proc cas;
   loadactionset "network";
   action patternMatch result=r status=s /
      direction      = "directed"
      links          = {name = "Links"}
      nodes          = {name = "Nodes"}
      linksQuery     = {name = "LinksQuery"}
      nodesQuery     = {name = "NodesQuery"}
      nodesVar       = {vars = "label"}
      nodesQueryVar  = {vars = "label"}
      outMatchNodes  = {name = "OutMatchNodes", replace=true}
      outMatchLinks  = {name = "OutMatchLinks", replace=true};
   run;
   print r.ProblemSummary; run;
   print r.SolutionSummary; run;
   action table.fetch / table = "OutMatchNodes" sortBy = {"match","nodeQ","node"}; run;
   action table.fetch / table = "OutMatchLinks" sortBy = {"match","from","to"}; run;
quit;

The problem summary output from this action is shown in Output 22.11.1.

The solution summary output from this action is shown in Output 22.11.2.

The output data table OutMatchNodes now contains the mapping from nodes in the query graph to nodes in the input graph for each pattern match, as shown in Output 22.11.3.

The output data table OutMatchLinks now contains the subgraphs for each pattern match, as shown in Output 22.11.4.

The results are displayed graphically in Output 22.11.5.

Output 22.11.5: Subgraphs