LOGSELECT Procedure

(View the complete code for this example.)

This example uses data from the "Six Cities" study of the effects of air pollution on health (Ware et al. 1984). The analysis concerns the 16 selected cases in Lipsitz et al. (1994). The response is binary and indicates the wheezing status of 16 children. The children were assessed at ages 9, 10, 11, and 12 years. A value of 1 for wheezing status indicates the occurrence of wheezing at that age. The following statements create the data set:

data mylib.six;
     input case city$ @@;
   do i=1 to 4;
      input age smoke wheeze @@;
      output;
   end;
   datalines;
 1 portage   9 0 1  10 0 1  11 0 1  12 0 0
 2 kingston  9 1 1  10 2 1  11 2 0  12 2 0
 3 kingston  9 0 1  10 0 0  11 1 0  12 1 0
 4 portage   9 0 0  10 0 1  11 0 1  12 1 0
 5 kingston  9 0 0  10 1 0  11 1 0  12 1 0
 6 portage   9 0 0  10 1 0  11 1 0  12 1 0
 7 kingston  9 1 0  10 1 0  11 0 0  12 0 0
 8 portage   9 1 0  10 1 0  11 1 0  12 2 0
 9 portage   9 2 1  10 2 0  11 1 0  12 1 0
10 kingston  9 0 0  10 0 0  11 0 0  12 1 0
11 kingston  9 1 1  10 0 0  11 0 1  12 0 1
12 portage   9 1 0  10 0 0  11 0 0  12 0 0
13 kingston  9 1 0  10 0 1  11 1 1  12 1 1
14 portage   9 1 0  10 2 0  11 1 0  12 2 1
15 kingston  9 1 0  10 1 0  11 1 0  12 2 1
16 portage   9 1 1  10 1 1  11 2 0  12 1 0
;

The mean response is modeled by using a logistic regression model. The explanatory variables are city of residence (city), age in years (age), and maternal smoking status at each age (smoke). The responses for each child are assumed to be equally correlated, indicating that an exchangeable correlation structure is appropriate. The following statements fit the model by using generalized estimating equations (GEEs) and the chosen correlation structure:

proc logselect data=mylib.six;
   class case city;
   model wheeze(event='1') = city age smoke;
   repeated subject=case / type=exch covb corrw printmle;
run;

The MODEL statement specifies the mean model for the wheeze response variable as a logistic regression that uses city, age, and smoke as explanatory variables. This is the same specification that you use for an ordinary logistic regression.

The REPEATED statement uses GEE for parameter estimation, specifies the working correlation structure, and controls the output that is displayed. The SUBJECT=CASE option specifies that the case variable identifies the individual subjects in the data set. The case variable must be listed in the CLASS statement. The TYPE=EXCH option specifies that the procedure use the exchangeable working correlation structure. The exchangeable correlation structure does not rely on an order in the repeated measurements, so you do not need to specify a within-subject effect in the WITHIN= option. The COVB option displays the parameter estimates covariance matrix, and the CORRW option displays the final working correlation matrix. The PRINTMLE option displays a table of the initial parameter estimates that are produced by maximum likelihood estimation.

The initial parameter estimates for the GEE fit are computed by an ordinary logistic regression, which assumes no dependence between the repeated measurements.

Output 18.6.1 displays general information about the GEE model fit.

Output 18.6.2 displays the estimated parameter covariance matrices. The COVB option produces both the model-based and empirical covariance matrices.

The working correlation matrix that is specified by the CORRW option is displayed in Output 18.6.3.

The exchangeable working correlation structure is characterized by a single parameter. Output 18.6.4 shows the table that contains this information.

Output 18.6.5 displays the "GEE Parameter Estimates" table. This table shows the parameter estimates, standard errors, chi-square values, and p-values for the parameter estimates. The table uses the empirical standard error estimates. You can also produce a table that uses the model-based standard error estimates by specifying the MODELSE option in the REPEATED statement.

You can compare the GEE parameter estimates to the parameter estimates from the initial model. The parameter estimates from the initial model are displayed in Output 18.6.6.

The GEE parameter estimates are not substantially different from the parameter estimates in the initial model.

The GEE parameter estimates in Output 18.6.5 and the empirical covariance matrix in Output 18.6.2 are used for subsequent processing by the ASSOCIATION, CTABLE, and LACKFIT options and the ODDSRATIO and OUTPUT statements.