RECENGINE Procedure

Note: Input data must be in a table that is accessible in your session. You can refer to this table by using a two-level name. The first level is a libref, and the second level is the table name. For more information, see the section Using SAS Viya Workbench in Chapter 2, Shared Concepts.

This example shows how to use the RECENGINE procedure to train a recommender system model on observations in a data table. The usersCommunity data set includes a subset of the click events over a period of time on a peer-to-peer-support community website. Each web page (item) on the site belongs to a message board that includes a number of topics of specific interest. The same user might have viewed the same web page multiple times. Also, in this data set, it is indicated whether or not the questions within the topic have been resolved. For each click event, the user ID and item ID are recorded. This data set includes 40,000 click events (observations).

The following code includes the DATA step that generates the data table mylib.usersCommunity. You can find the complete DATA set here:

https://support.sas.com/documentation/onlinedoc/viya/examples.htm

You can load the usersCommunity data table into your SAS library by using your libref as in the following statements:

   data mylib.usersCommunity;
      input itemid boardid userid isSolvedTopic;
      datalines;
      38 4817 6313 0
      15 7589 1355 1
      46 9560 2926 1
      16 11635 3985 1
      38 13023 4163 0

   ... more lines ...   

The following statements train a recommender system model on the usersCommunity data by using PROC RECENGINE:

proc recengine data=mylib.usersCommunity method=bpr nthreads=1 outmodel=mylib.factors;
   input userid itemid/level=nominal;
   userid userid;
   itemid itemid;
   bpr maxIter=20 nFactors=10 learnStep=0.01 regl2=0.01 seed=1;
   savestate rstore=mylib.state;
run;

The following statements print the first 10 observations in the mylib.factors data table, which includes some of the rows that are related to the latent factors for users. The output is shown in Figure 1.

proc print data=mylib.factors(obs=10);
run;

The following statements print the last 10 observations in the mylib.factors data table, which includes some of the rows that are related to the latent factors for items. The output is shown in Figure 2.

data _null_;
   if 0 then set mylib.factors nobs=n;
   call symputx("n",left(put(n,best.)),'l');
run;

proc print data=mylib.factors(firstobs=%eval(&n-10));
run;

You can use the mylib.factors output table to rank items for each user. The following code shows how to find the top two items for a sample user (that is, the one whose user ID is 6313).

First, you create the scoring data table that includes the ID of the sample user of interest:

   data mylib.user6313;
   input   userid;
   datalines;
   6313
   ;
   run;

Next, you use the ASTORE procedure to score this user:

proc astore;
   setoption REC_TOP_N 2;
   score data=mylib.user6313 rstore=mylib.state out=mylib.rankedItems;
   run;
quit;

The following statements print the top two recommended items for user 6313. The output is shown in Figure 3.

proc print data=mylib.rankedItems;
run;