GPREG Procedure

Note: Input data must be in a table that is accessible in your session. You can refer to this table by using a two-level name. The first level is a libref, and the second level is the table name. For more information, see the section Using SAS Viya Workbench in Chapter 2, Shared Concepts.

This example uses the Sinewave data set to demonstrate how you can use the GPREG procedure to perform Gaussian process regression analysis and save the trained model in an analytic store. The Sinewave data set contains 1,000 noisy samples from a two-dimensional sine wave function; it has two variables, x and y.

The following DATA steps generate the Sinewave data set and upload it to your session:

data Sinewave;
   keep x y;
   call streaminit(123);       /* set random number seed */
   do i = 1 to 1000;
      u = rand("Uniform");
      x = u;
      y = sin(6*x)+rand("Normal", 0, 0.01);
      output;
   end;
run;

data mylib.sinewave;
   set Sinewave;
run;

The second DATA step assumes that your libref is named mylib, but you can substitute any appropriately named libref.

The following statements use PROC GPREG to perform Gaussian process regression on the data and save the data in an analytic store:

proc gpreg
   data=mylib.sinewave
   seed=12345
   nThreads=32
   nInducingPoints=10
   fixInducingPoints
   outInducingPoints=mylib.gpreg_ip
   outVariationalCov=mylib.gpreg_cov;
   target y/level=interval;
   input x;
   partition fraction(valid=0 test=0.2 seed=1235);
   kernel rbf(
      autoRelevanceDetermination
      fixKernelParmFirstIter
      jitterMaxIters=10
      );
   optimization adam(
      regl1=0.5
      maxiters=500
      learningRate=0.05
      momentum=0.8
      adaptiveRate
      adaptiveDecay=0.9
      printfreq=200
   );
    savestate rstore=mylib.astore;
    output out=mylib.score copyvars=(x y);
    display nObs varStats modelInfo ParameterEstimates;
run;

These statements assume that your libref is named mylib, but you can substitute any appropriately defined libref.

PROC GPREG generates four ODS tables, which are shown in Figure 1 through Figure 4.

In this example, PROC GPREG generates the score output table mylib.score. The following statements print the first 15 rows of the table, which is shown in Figure 5. The value 1 in the _ROLE_ column means that the observation has a training role, and the value 3 in the _ROLE_ column means that the observation has a testing role.

proc print noobs data=mylib.score (obs=15);
run;