GPCLASS Procedure

Note: Input data must be in a table that is accessible in your session. You can refer to this table by using a two-level name. The first level is a libref, and the second level is the table name. For more information, see the section Using SAS Viya Workbench in Chapter 2, Shared Concepts.

This example uses the Iris data table to demonstrate how to use the GPCLASS procedure to perform classification. There are three clusters in the Iris data. First, the observations are separated into two classes: rows of the species Setosa are labeled as class 1, and rows of the species Versicolour and Virginica are labeled as class 0. Then the data are split into subsets for training and testing. The following DATA steps generate the Iris data:

data iris;
   set sashelp.iris;
run;

data iris_binary_class;
   set iris;
   if Species = 'Setosa' then label=1;
   else label=0;
run;

data mylib.iris_train;
   set iris_binary_class(obs=140);
run;

data mylib.iris_test;
   set iris_binary_class(firstobs=141 obs=150);
run;

These statements assume that your libref is named mylib, but you can substitute any appropriately defined libref.

The following statements run PROC GPCLASS and output the results to data tables and ODS tables. In this example, a linear kernel is used to separate the two classes.

proc gpclass
   data=mylib.iris_train
   testdata=mylib.iris_test
   seed=12345
   nThreads=32
   link=Logit;
   input SepalLength SepalWidth PetalLength PetalWidth;
   target label/level=nominal;
   kernel linear(constant=0);
   inference LA(maxIter=100 threshold=0.001);
   output out=mylib.iris_score copyvars=(_all_);
   display nObs descStats modelInfo iterStats;
run;

PROC GPCLASS generates four ODS tables, which are shown in Output 14.1.1 through Output 14.1.4.

In this example, PROC GPCLASS generates the classification score table mylib.iris_score, which lists the predicted class labels and probabilities. The following statements print the table shown in Output 14.1.5:

proc print noobs data=mylib.iris_score;
run;

From the score table, you can see that by using a simple linear kernel, PROC GPCLASS produces a perfect prediction of good confidence, with the predicted probabilities close to 1.