The FACTMAC Procedure

This example draws on data that are derived from companies that provide movies for online viewing. A company wants to offer its customers recommendations of movies that they might like. These recommendations are based on ratings that are provided by users. The MovieLens data set was developed by the GroupLens project at the University of Minnesota and is available at http://grouplens.org/datasets/movielens. This example uses the MovieLens 100K version.

There are four columns in the MovieLens 100K data set: user ID, item ID (each item is a movie), timestamp, and rating. This example predicts the rating for a specified user ID and an item ID. The data set is very sparse because most combinations of users and movies are not rated.

You can download the compressed archive file from the website at http://files.grouplens.org/datasets/movielens/ml-100k.zip and use any third-party unzip tool to extract all the files in the archive to the destination directory of your choice. ^[3] The file that contains the ratings is u.data. Assuming the directory is /dept/app/doc/vb023/en/src/casml/factmac, the following DATA step loads the data table from the directory into your CAS session:

 proc casutil;
     load file="u.data"
     /*or other user-defined location*/
     casout="movlens"
     importoptions=(filetype="CSV" delimiter="TAB" getnames="FALSE"
                    vars=("userid" "itemid" "rating" "timestamp"));
 run;

The following statements show how to use PROC FACTMAC to predict movie ratings:

proc factmac data=mycas.movlens nfactors=10 learnstep=0.15
             maxiter=20  outmodel=mycas.factors;

   input userid itemid /level=nominal;
   target rating /level=interval;
   output out=mycas.out1 copyvars=(userid itemid rating);
run;

The following statements print the first 10 observations in the mycas.factors data table, which is specified in the OUTMODEL= option in the PROC FACTMAC statement. The output is shown in Figure 2.

proc print data=mycas.factors(obs=10);
run;

The following statements print the predicted movie ratings for the first 20 observations, as shown in Figure 3.

proc print data=mycas.out1(obs=20);
run;