NETWORK Procedure

When you are trying to understand the roles of certain entities in a social network, a typical workflow is to first divide the network into communities and then calculate centrality metrics on the induced subgraphs defined by those communities. You can process these induced subgraphs of the original input graph with only one call to PROC NETWORK by using the BY statement. This section presents an example of how to use the COMMUNITY statement, followed by the CENTRALITY statement in conjunction with the BY statement.

Consider the graph depicted in Figure 230.

The following statements create the data table mylib.LinkSetIn:

data mylib.LinkSetIn;
   input from $ to $ @@;
   datalines;
A B  A C  A D  B C  C D
C E  D F  F G  F H  F I
G H  G I  I J  J K  J L
K L
;

First, call the community detection method as follows:

proc network
   links     = mylib.LinkSetIn
   outNodes  = mylib.OutNodesComms
   outLinks  = mylib.OutLinksComms;
   community;
run;

The resulting output is a partition of the links and nodes of the original graph into communities.

The data table that contains the assignment of nodes to communities, mylib.OutNodesComms, is shown in Output 2.8.1.

The data table that contains the assignment of links to communities, mylib.OutLinksComms, is shown in Output 2.8.2.

The graph seems to have three distinct parts, which are connected by just a few links. The induced subgraphs on these communities are shown in blue in Figure 231 through Figure 233.

Now, using one call to PROC NETWORK, you can calculate the centrality metrics for all three induced subgraphs by using the BY statement and the links partition defined by the community detection algorithm. In addition, because these subgraphs are completely independent, the processing is done in parallel across machines and threads (depending on your server configuration).

proc network
   links        = mylib.OutLinksComms(where=(community_1 ne .))
   outNodes     = mylib.NodeSetOut;
   centrality
      degree    = unweight
      influence = unweight
      close     = unweight
      between   = unweight
      eigen     = unweight;
   displayout
      ProblemSummary  = ProblemSummary
      SolutionSummary = SolutionSummary;
   by community_1;
run;
%put &_NETWORK_;

Assuming that your grid has a total of at least three cores, all three subgraphs are processed simultaneously with one call to PROC NETWORK. The progress of the procedure is shown in Output 2.8.3.

Notice that links that connect different partitions have been removed by using a WHERE clause on the LINKS= option in the PROC NETWORK statement.

The output table mylib.ProblemSummary contains a summary of each induced subgraph that is processed by PROC NETWORK.

The output table mylib.SolutionSummary contains a solution summary for the processing on each of the induced subgraphs.

The centrality results (by community) are shown in Output 2.8.6.