The HPCLUS Procedure

In this example, PROC HPCLUS clusters nominal variables in the Soybean data set, which is from the UCI Machine Learning Repository at http://archive.ics.uci.edu/ml/datasets/Soybean+%28Small%29.^[2]The Soybean data set includes 47 observations, each of which has 35 variables. Each observation is labeled as one of four diseases: , , , and . Diseases , , and have 10 observations each, and disease has 17 observations. For more detailed data information, see Lichman (2013). All the variables in this data set are used in this example.

You can execute the following SAS code to generate the SAS data set:

%let base = http://archive.ics.uci.edu/ml/machine-learning-databases/soybean;
%let _INPUTNOMVAR = date plantstand precip temp hail
crophist areadamaged severity seedtmt
germination plantgrowth leaves
leafspotshalo leafspotsmarg leafspotsize
leafshread leafmalf leafmild stem
lodgings stemcankers cankerlesion
fruitingbodies externaldecay mycelium
intdiscolor sclerotia fruitpods fruitspots
seed moldgrowth seeddiscolor seedsize
shriveling roots;


data soybean;
length soybeanID 8;
infile "&base/soybean-small.data" device=url delimiter=',';
input &_INPUTNOMVAR. classID $ ;
soybeanID = _N_;
run;

The following statements run the k-modes clustering algorithm with a frequency-based distance measure (DISTANCENOM=RELATIVEFREQ) and check whether the clusters that the procedure obtains match the labels of the observations in the data set:

proc hpclus data=soybean maxiter=10 maxc=4 DISTANCENOM= RELATIVEFREQ
  outstat=outstat outiter ;
  input &_INPUTNOMVAR. / level=nominal;
   id classID soybeanID ;
  score out=out_hpclus1;
run;

proc sort data=out_hpclus1;
  by _cluster_id_;
run;

title " ";
proc freq data=out_hpclus1;
   by _CLUSTER_ID_;
   table classID  ;
run;

Output 5.3.1 shows the cluster summary table that is produced for four clusters.

Output 5.3.2 shows some of the entries from the descriptive statistics table that is produced for each nominal input variable. This table shows the frequencies of levels for the input nominal variables in the data set.

Output 5.3.3 shows some of the entries from the within-cluster frequencies table that is produced for each cluster. This table shows frequencies of levels for the input nominal variables in each cluster. The table shows some information about how the levels of variables are distributed in each cluster, which is important for intracluster similarity.

Output 5.3.4 through Output 5.3.7 show whether the observations are classified correctly with respect to the specified labels of observations (, , , and ). Output 5.3.4 shows that all observations that belong to class are in cluster 1. Similarly, all observations that belong to classes , , and are in clusters 2, 3, and 4, respectively. Thus, you can conclude that the clustering algorithm classified the observations accurately for this example without using the labels in an unsupervised approach.